Automatisation copie de CD (data) vers dossier [Résolu], Insertion de CD, copie des données, éjection du CD

[funkyfrogg]

Avex deux GROS classeurs plein de CDs et de DVDs de données (PAS de musique, ni de films) que j'aimerais copier sur un disque dur externe, je recherche une solution d'automatisation.
Les résultats de recherches Google sont passables; beaucoup de résultats sont autour de la copie de musique ou de films alors que je cherche seulement à rapatrier des données.

Jusqu'à présent:
— Automator ne semble pas être en mesure de reconnaitre de nouveaux volumes quand ils montent sur le desktop, et ne réalise donc que la moitié du boulot
— je n'ai pas vu de scripts Applescripts à ce sujet.

Merci pour votre aide!

[poissonfree]

Sur PC, j'aurais fait un .bat sous DOS.
L'avantage, c'est que quelque soit le nom du volume, c'est toujours lié à la même lettre ( genre D: ).
Donc là sous Mac OS, comme sous Linux, aucune idée de comment procéder

[Guest_JacqR_*]

Voici un script AppleScript qui fait cela pour les CD ou les DVD).
Le script fonctionne sur Mavericks ou sur une version de OS X moins récente, je ne sais pas pour Yosemite

Code

set destination to (choose folder with prompt "Sélectionnez le disque externe pour copier vos CD ou les DVD.") as text
repeat
    set r to do shell script "/usr/bin/drutil status | grep  '\\(Type:\\|Writability:.*blank\\)'"
    if " blank" is in r then
        do shell script "/usr/bin/drutil eject"
    else if "No Media Inserted" is not in r then
        set cd_DVDpath to do shell script "tID=$(/usr/bin/grep -o '/dev/disk[0-9]*' <<< " & (quoted form of r) & "); /bin/df | /usr/bin/grep \"$tID\" | /usr/bin/sed 's/.*\\/Volumes\\//\\/Volumes\\//'"
        set dvdName to (cd_DVDpath as POSIX file) as text
        set n to ""
        set i to 0
        try -- vérifie que le dossier (le nom du CD/DVD) n'existe pas sur le disque externe, sinon on ajoute un nombre après le nom
            repeat
                (destination & dvdName & n) as alias
                set i to i + 1
                set n to " " & i
            end repeat
        end try
        set dest to quoted form of (POSIX path of (destination & dvdName & n))
        do shell script "/usr/bin/ditto -X --nocache " & (quoted form of cd_DVDpath) & "  " & dest & ";/usr/bin/drutil eject"
    end if
    delay 3
end repeat

Lors de l'exécution du script un dialogue s'affichera, il suffit de choisir votre disque externe ou un dossier sur le disque externe.

[JMGGG]

Bonjour,

CCC (CarbonCopyCloner)
Personal Backup
…
Entre autres.

Et cela te fera de l'incrémental…

JMGGG

[trouspinette]

Et en script Bash (à fignoler mais j(ai vite testé et c'est OK).

Code

#!/bin/bash

# BASH Script pour copier le contenu d'un CD vers au autre volume
# Remplacer /dev/disk1s0 par le nom du /dev de votre configuration
# Contraintes : PAS d'espaces dans le nom des CD/DVD

# Variables

myEGREP='/usr/bin/egrep'
myDF='/bin/df'
myAWK='/usr/bin/awk'
myMKDIR='/bin/mkdir'
myCUT='/usr/bin/cut'
myCHMOD='/bin/chmod'
myRSYNC='/usr/bin/rsync'
myDATE=`/bin/date +"%Y_%m_%d"`

# Destinations des copies
# Remplacer ZZZ_CD par chemin réel désiré
myTARGET_DIR="/ZZZ_CD"

# On stocke le nom du volume
myOpticalDrive=$($myDF -hP | $myEGREP '^/dev/disk1s0' | $myAWK '{ print $6 }' | $myCUT -d'/' -f3)

# On créé une arborescence pour le CD traité
# => Ajout de la date de traitement au dossier créé pour éviter d'écraser si présent
$myMKDIR -p $myTARGET_DIR/$myOpticalDrive-$myDATE

# myFINAL_TARGET
myFINAL_TARGET="$myTARGET_DIR/$myOpticalDrive-$myDATE"

# Lecture/ecriture pour tous sur la cible, si on a un soucis de droits
#myCHMOD -R 777 $myFINAL_TARGET

# On copie le contenu du CD
$myRSYNC -aEpv /Volumes/$myOpticalDrive/ /$myFINAL_TARGET

# Diskuil pour ejecter le CD
# Et d'autres blabla à venir

[funkyfrogg]

Voici un script AppleScript qui fait cela pour les CD ou les DVD).
Le script fonctionne sur Mavericks ou sur une version de OS X moins récente, je ne sais pas pour Yosemite

Ma machine est toujours sous 10.7.5 (et ne peux pas aller au dessus d'ailleurs)…
Si près du but!

CCC (CarbonCopyCloner)
Personal Backup

J'utilise la dernière version gratuite de CCC (et non pas la plus récente, payante). Il est possible d'automatiser la copie RÉCURRENTE de volumes. Ce n'est pas le cas de ce projet. Chaque copie ne sera réalisée qu'une fois.

Et en script Bash (à fignoler mais j(ai vite testé et c'est OK).

[code]#!/bin/bash

# BASH Script pour copier le contenu d'un CD vers au autre volume
# Remplacer /dev/disk1s0 par le nom du /dev de votre configuration
# Contraintes : PAS d'espaces dans le nom des CD/DVD

Hélas! La vaste majorité des CD/DVD d'archives que j'ai contiennent un espace dans leur nom…


En tout cas, merci pour le temps passé sur ce problème. J'apprécie beaucoup!

[Guest_JacqR_*]

Bonjour,

Voici un script AppleScript qui fait cela pour les CD ou les DVD).
Le script fonctionne sur Mavericks ou sur une version de OS X moins récente, je ne sais pas pour Yosemite

Ma machine est toujours sous 10.7.5 (et ne peux pas aller au dessus d'ailleurs)…
Si près du but!

Non, le script va fonctionner sans problème sur ton 10.7.5, car il fonctionne bien sur OS X 10.5.8, donc OS X versions 10.9.5 ou moins, seulement la version 10.10.+ (Yosemite) que je ne sais pas, car je ne l'ai pas télécharger sur mon Mac pour le tester.

[Bernard3375]

Cela fait plusieurs fois que je lis ce sujet, mais je n'arrive pas à comprendre la question…
C'est quoi le problème ? (pour le béotien que je suis…)

[poissonfree]

Ben il a un gros stock de CD/DVD (il ne sait pas ce qu'il y a dessus, donc capacité variable) qu'il veut mettre sur un disque dur pour traiter les données plus facilement

[Bernard3375]

Ben il a un gros stock de CD/DVD (il ne sait pas ce qu'il y a dessus, donc capacité variable) qu'il veut mettre sur un disque dur pour traiter les données plus facilement

Oui, ça j'ai compris, mais en quoi est-ce un problème ?
La question est : comment ouvrir automatiquement à l'insertion et transférer toujours automatiquement sur le disque externe ?

Ce message a été modifié par Bernard3375 - 2 Jan 2015, 17:34.

[baron]

Transférer automatiquement sur disque dur le contenu de nombreux CD, en n'ayant qu'à les insérer dans le lecteur pour que la copie se lance.

[Grillé…]

Ce message a été modifié par baron - 2 Jan 2015, 17:34.

[Bernard3375]

Transférer automatiquement sur disque dur le contenu de nombreux CD, en n'ayant qu'à les insérer dans le lecteur pour que la copie se lance.

[Grillé…]

Il n'y avait pas ça dans "classic" ? Autorun ou un truc comme ça ?

[funkyfrogg]

Non, le script va fonctionner sans problème sur ton 10.7.5, car il fonctionne bien sur OS X 10.5.8, donc OS X versions 10.9.5 ou moins, seulement la version 10.10.+ (Yosemite) que je ne sais pas, car je ne l'ai pas télécharger sur mon Mac pour le tester.

Je ne sais pas pourquoi, le script se lance bien (j'ai une demande de destination) mais ne copie pas quand un CD ou DVD est inserré.
J'ai viré tout les disques externes (HD ou non) et recommencé avec un DVD (plein de data, PAS vierge)… Rien.
Le script a été lancé depuis Applescript: rien. En tant qu'application: rien.

J'ai oublié quelque chose d'évident?

[Guest_JacqR_*]

Bonjour,

Non, le script va fonctionner sans problème sur ton 10.7.5, car il fonctionne bien sur OS X 10.5.8, donc OS X versions 10.9.5 ou moins, seulement la version 10.10.+ (Yosemite) que je ne sais pas, car je ne l'ai pas télécharger sur mon Mac pour le tester.

Je ne sais pas pourquoi, le script se lance bien (j'ai une demande de destination) mais ne copie pas quand un CD ou DVD est inserré.
J'ai viré tout les disques externes (HD ou non) et recommencé avec un DVD (plein de data, PAS vierge)… Rien.
Le script a été lancé depuis Applescript: rien. En tant qu'application: rien.

J'ai oublié quelque chose d'évident?

Non, vous n'avez rien oublié, il y a certainement quelque chose de différent par rapport à mes 2 Macs où j'ai testé le script, on va essayer de trouver la différence.

Est-ce que votre superdrive (Lecteur-graveur CD et DVD‎) est externe ou interne ?
Pouvez-vous me donner l'historique du script dans l'éditeur de script ?

Aussi, insérer votre DVD de données, attendez qu'il soit monté, exécuter ce script dans l'éditeur de script

Code

set r to "-- Commande status :" & return
set r to r & (do shell script "/usr/bin/drutil status ")
set r to r & return & "-- Commande df :" & return
set r to r & (do shell script "/bin/df")

set res to do shell script "/usr/bin/drutil status | grep  '\\(Type:\\|Writability:.*blank\\)'"
set cd_DVDpath to do shell script "tID=$(/usr/bin/grep -o '/dev/disk[0-9]*' <<< " & (quoted form of res) & "); /bin/df | /usr/bin/grep \"$tID\" | /usr/bin/sed 's/.*\\/Volumes\\//\\/Volumes\\//'"

set r to r & return & return & "-- CD/DVD path :" & cd_DVDpath
return r

Donnez-moi le texte du résultat dans la fenêtre de l'éditeur.


Si votre Lecteur-graveur CD et DVD est externe :

Exécuter ce script

Code

do shell script "/usr/bin/drutil eject"

Est-ce que cette commande éjecte le DVD ?

Exécuter ce script

Code

do shell script "drutil eject -drive external"

Est-ce que cette commande éjecte le DVD ?

[funkyfrogg]

Est-ce que votre superdrive (Lecteur-graveur CD et DVD‎) est externe ou interne ?

Ma machine a 3 lecteurs: deux lecteurs internes en fin de vie et un lecteur USB externe (mon lecteur principal).

Pouvez-vous me donner l'historique du script dans l'éditeur de script ?

Voici l'historique:

CODE

tell application "AppleScript Editor"
choose folder with prompt "Sélectionnez le disque externe pour copier vos CD ou les DVD."
--> alias "Speedy:Users:Aldo:Desktop:test:"
end tell
tell current application
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
do shell script "/usr/bin/drutil status | grep '\\(Type:\\|Writability:.*blank\\)'"
--> " Type: No Media Inserted
Type: No Media Inserted
Type: CD-R Name: /dev/disk13"
Result:
error "User canceled." number -128

Aussi, insérer votre DVD de données, attendez qu'il soit monté, exécuter ce script dans l'éditeur de script

Code

set r to "-- Commande status :" & return
       set r to r & (do shell script "/usr/bin/drutil status ")
       set r to r & return & "-- Commande df :" & return
       set r to r & (do shell script "/bin/df")
      
       set res to do shell script "/usr/bin/drutil status | grep  '\\(Type:\\|Writability:.*blank\\)'"
       set cd_DVDpath to do shell script "tID=$(/usr/bin/grep -o '/dev/disk[0-9]*' <<< " & (quoted form of res) & "); /bin/df | /usr/bin/grep \"$tID\" | /usr/bin/sed 's/.*\\/Volumes\\//\\/Volumes\\//'"
      
       set r to r & return & return & "-- CD/DVD path :" & cd_DVDpath
       return r

Donnez-moi le texte du résultat dans la fenêtre de l'éditeur.

Voici le texte du résultat:

CODE

"-- Commande status :
Vendor Product Rev
PIONEER DVD-RW DVR-111D AB09

Type: No Media Inserted

Vendor Product Rev
PIONEER DVD-RW DVR-111D 1.19

Type: No Media Inserted

Vendor Product Rev
BUFFALO Optical Drive 2.00

Type: CD-R Name: /dev/disk13
Sessions: 1 Tracks: 1
Overwritable: 00:00:00 blocks: 0 / 0.00MB / 0.00MiB
Space Free: 00:00:00 blocks: 0 / 0.00MB / 0.00MiB
Space Used: 40:38:66 blocks: 182916 / 374.61MB / 357.26MiB
Writability:

-- Commande df :
Filesystem 512-blocks Used Available Capacity Mounted on
/dev/disk0s2 998536000 832935896 165088104 84% /
devfs 266 266 0 100% /dev
/dev/disk1s2 3906357344 3645472288 260885056 94% /Volumes/Medias
/dev/disk3s2 3906357344 2589795840 1316561504 67% /Volumes/Goodzilla
/dev/disk2s2 1952853344 1851192352 101660992 95% /Volumes/Travaux
map -hosts 0 0 0 100% /net
map auto_home 0 0 0 100% /home
/dev/disk6s2 1952853344 1439270224 513583120 74% /Volumes/Archive A
/dev/disk10s2 1952853344 1818738016 134115328 94% /Volumes/Travaux_BackUp_2 1
/dev/disk11s2 3906357344 3881707568 24649776 100% /Volumes/Medias Back-Up 2
/dev/disk8s2 3906357344 3510427640 395929704 90% /Volumes/Speedy Clone 2
/dev/disk9s1 62440320 16491776 45948544 27% /Volumes/EOS_DIGITAL
/dev/disk5s2 3906357344 3060837616 845519728 79% /Volumes/Goodzilla Mograph BackUp 2
/dev/disk7s2 3906357344 2560013328 1346344016 66% /Volumes/TimeMachine
/dev/disk12s1 921520 779464 142056 85% /Volumes/SketchUp 2015 (English)
/dev/disk13s1s2 730960 730960 0 100% /Volumes/Tout Gondry #03

-- CD/DVD path :/Volumes/Tout Gondry #03"

Si votre Lecteur-graveur CD et DVD est externe :
Exécuter ce script

Code

do shell script "/usr/bin/drutil eject"

Est-ce que cette commande éjecte le DVD ?

Oui.

Exécuter ce script

Code

do shell script "drutil eject -drive external"

Est-ce que cette commande éjecte le DVD ?

Oui. Egalement.

Merci!

[Guest_JacqR_*]

Bonjour,

Cela ne fonctionnait pas à cause des multiples lecteurs, le script obtenait toujours "Type: No Media Inserted" pour un des lecteurs.

Voici le script modifié, il vérifiera les 3 lecteurs séparément :

Code

set destination to (choose folder with prompt "Sélectionnez le disque externe pour copier vos CD ou les DVD.") as text
repeat
    repeat with j from 1 to 3
        set r to ""
        try
            set r to do shell script "/usr/bin/drutil -drive " & j & " status | grep  'Type:.*Name: /dev/disk'"
        end try
        if "/dev/disk" is in r then
            set cd_DVDpath to do shell script "tID=$(/usr/bin/grep -o '/dev/disk[0-9]*' <<< " & (quoted form of r) & "); /bin/df | /usr/bin/grep \"$tID\" | /usr/bin/sed 's/.*\\/Volumes\\//\\/Volumes\\//'"
            if cd_DVDpath is not "" then
                set dvdName to (cd_DVDpath as POSIX file) as text
                set n to ""
                set i to 0
                try -- vérifie que le dossier (le nom du CD/DVD) n'existe pas sur le disque externe, sinon on ajoute un nombre après le nom
                    repeat
                        (destination & dvdName & n) as alias
                        set i to i + 1
                        set n to " " & i
                    end repeat
                end try
                set dest to quoted form of (POSIX path of (destination & dvdName & n))
                do shell script "/usr/bin/ditto -X --nocache " & (quoted form of cd_DVDpath) & "  " & dest & ";/usr/bin/drutil -drive " & j & " eject"
            end if
        end if
    end repeat
    delay 3
end repeat

Important, ce script ne fonctionnera pas avec des CD/DVD ré-inscriptibles gravés en plusieurs sessions (aucun problème pour ceux gravés en une seule session).

[funkyfrogg]

Salut JacqR!

Je viens de faire un test et tout fonctionne! C'est super!
Si tu veux que je fasse une petite donation vers un compte paypal ou une association de ton choix, n'hésite pas!

Merci!

[trouspinette]

Salut JacqR!

Je viens de faire un test et tout fonctionne! C'est super!
Si tu veux que je fasse une petite donation vers un compte paypal ou une association de ton choix, n'hésite pas!

Merci!

Je tenais à féliciter funkyfrogg pour cette action : bravo de proposer ainsi une rétribution ! Bravo aussi à JacqR pour son aide sur le sujet, qui n'a certainement pas travaillé sur une optique pécuniaire à aider l'auteur.

Vous honorez chacun par votre attitude la fonction d'entraide sur ce forum ;-)

[baron]

Oui, c'est un grand plaisir de lire vos échanges !

(Il me semble qu'on n'attribue plus guère de titres perso…?)

[funkyfrogg]

Macbidouilleur de BRONZE! Whoa dude. Merci les gars!

Pendant mes CDs sont automatiquement copiés, j'en profite pour voir un bon filim.

Ce message a été modifié par funkyfrogg - 2 Feb 2015, 22:48.

[funkyfrogg]

Bonjour bonjour! Voici une petite update.

Après une interruption de plusieurs années (j'avais du arréter parce que je n'avais pas assez de place sur mes disques), j'ai enfin le courage de reprendre le transfert de tout ces CDs et DVDs vers des HD classiques et mais bien plus volumineux et maintenant plus abordable.

Le script marche toujours! Il fonctionne à merveille. Quel time saver!

Pour aller plus vite, j'ai acheté un autre lecteur de DVDs pour voir si je pouvais diviser par deux la tache en utilisant simultanement deux fois le même script. Malheureusement les scripts ne reconnaissent qu'un seul CD/DVD (le premier qui apparaît) et le recopient deux fois.

Est-il possible de continuer en utilisant Apple Script ou faut-il simplement créer une petite application dédiée?

Merci d'avance!

[sinbad21]

Tu peux par exemple dupliquer le script et supprimer le repeat sur la variable j en le remplaçant par une constante. Remplacer :

Code

repeat with j from 1 to 3
        set r to ""

par

Code

set r to ""
set j to 1  -- ou 2 ou 3 selon le lecteur

et en bas du script supprimer l'avant dernier end repeat, qui termine le repeat sur la variable j.

Tu crées 1 script avec j = 1, un script avec j = 2 et un script avec j = 3 et tu pourras lancer les 3 en même temps.