copie d'arborescence avec des alias

[zerod]

Bonjour tout le monde,

J'ai voulu copier ma bibliothèque iPhoto vers un dossier, j'ai donc fait :

cp -rp Pictures/iPhoto Library/Originals/* dossier

puis :
cp -rp Pictures/iPhoto Library/Modified/* dossier pour écraser les originaux modifiés que je ne souhaite pas garder.

Le soucis c'est que lors de précédentes importations de photo iPhoto m'a crée des alias au lieu de recopier les originaux (que j'ai conservé heureusement), et donc la copie, copie les alias et non les fichiers ciblés

Connaissez-vous une option de cp ou une meilleure méthode pour faire cet export ?

Un grand merci d'avance si c'est le cas

[JMGGG]

Bonjour,
??? Quest-ce que ces cp -rp ???
Il suffit de glisser le contenu de tes événement dans un dossier posé sur ton bureau.
JMGGG

[zerod]

Non si je fais cela je vais avoir une copie de ma bibliothèque avec des alias, ce que je veux faire c'est avoir toutes mes photos dans un dossier (avec le classement actuel d'iphoto par année) mais que les alias a l'intérieur soient remplacés par les fichiers pointés par ces alias, afin par exemple d'exporter ce dossier autonome sur ma freebox ou sur tout autre pc non Mac

Cp -rp dans un terminal c'est une copie d'une arborescence en gardant les date / proprio/ etc. Des fichiers

Je suis plus clair ?

Ce message a été modifié par zerod - 25 Apr 2011, 16:22.

[GhisDiem]

Tu ne peux pas faire ça, le dossier librairie de iPhoto fait sa petite cuisine en privé. Il crée des alias dans des dossiers pour simplifier le rangement que tu adoptes dans iPhoto.
Si tu veux adopter ce rangement en dehors de iPhoto, un seul moyen, copier toutes les photos dans un dossier sur le disque dur et créer toi-même tes sous-dossiers…

Si c'est juste une copie de la bibliothèque que tu veux faire pour une sauvegarde ou autre, il faut copier tout le dossier librairie et le renommer of course, ou le copier sur un disque externe…
Ou alors, je ne comprends vraiment pas ta question !!

[zerod]

concrètement je veux :
- exporter toutes mes photos sur ma freebox v6 pour les visionner sur la tv
- switcher de iphoto à picasa

si je copie la bibliothèque, chose que je fais déjà sur un serveur distant pour la sauvegarder je n'ai pas toutes mes photos, j'ai tout un tas d'alias qui pointent vers divers dossiers photo que j'ai importé lors de mon passage sur mac il y a 2/3 ans...

[baron]

Pourquoi n'utilises-tu pas la commande exporter d'iPhoto ?

Utilise les ressources de Mac OS — comme suggéré par JMGGG— ou celles d'iPhoto, ça fera ce que tu eux.
A vouloir travailler en Unix, tu te compliques la tâche — ou alors je n'ai rien compris à ta demande…

[GhisDiem]

Je crois que je commencerais par nettoyer mon Mac de ces alias issus du monde PC… Il me semble que continuer à vouloir utiliser un iPhoto plein de bidules pas exploitables et une erreur…
Après, tu y verras plus clair pour faire ce que tu veux faire…
Ça m'arrive constamment de passer des dossiers photos de Mac à PC et vis versa… Ces fichiers fantômes peuvent devenir pénibles !!! Mais j'ai a chaque fois fait le tri avant de transférer sur iPhoto…

[zerod]

Baron : la commande exporter ne crée pas un dossier par évènement, elle mets tout à plat... et j'ai 18000 photos....

GhisDiem : a mais j'aimerai bien me débarasser de ces alias, qui ont été crées par iphoto lors de la première importation de mes photos précédentes ! Mais je cherchais un moyen alernatif à me taper tous les évènements à la main pour écraser les alias avec les fichiers qu'ils pointent.

schématiquement actuellement j'ai :

iPhoto library / Originals / 1996 1997 ... 2011

et dans un dossier "photos" au même niveau les albums que j'avais importé lors de mon switch sur mac, ce sont ces albums qui au lieu d'avoir été recopiés dans la librairie iphoto sont pointés dans celle ci sous forme d'alias. Problème, il y en a beaucoup, et ils ne sont pas classés par année comme dans la librairie iphoto, ce serait trop facile

j'ai vu un outils pour exporter depuis iphoto, phoshare, je vais tester.

Ce message a été modifié par zerod - 26 Apr 2011, 07:16.

[baron]

Bonsoir,

Je ne suis vraiment pas sûr de pouvoir t'aider…

Je te dis quand même en vitesse ce que je peux (mais je suis novice avec OSX et iPhoto…) :

• Quand j'ouvre ma bibliothèque iPhoto comme paquet (clic droit dans le Finder) pour voir son contenu, mes vraies photos sont toutes dans un dossier Masters ; les dossiers Originals et Modified sont des alias.
Il faut dire aussi que dans les Prefs d'iPhoto, j'ai sélectionné l'option de chaque fois copier la photo dans la bibliothèque plutôt que d'accepter des alias…

• Si tu obtiens un dossier avec plein d'alias, peut-être qu'un utilitaire comme FileBuddy pourrait t'aider ?
http://www.macvf.fr/fiche_produits/dynamic...ile%20Buddy%209

• Il ne m'a pas semblé qu'iPhoto Library manager (utilitaire bien pratiue par ailleurs) puisse être utile ici.

[zerod]

je suis parti pour tout faire à la main... c'est long
je n'ai pas le master moi

[Guest_EricaL**_*]

Bonjour,


Voici un script AppleScript qui remplace tous les alias par les fichiers originaux.
Les originaux seront copiés, ils ne seront pas déplacés.

Code

remplaceAliasParOriginal((choose folder) as list) --  le dossier où les photos ont été copiées


on remplaceAliasParOriginal(thesefolders)
    tell application "Finder"
        repeat with tFolder in thesefolders
            repeat with thisAlias in (get alias files of tFolder)
                try
                    duplicate (get original item of thisAlias) to tFolder with replacing
                end try
            end repeat
            my remplaceAliasParOriginal(get folders of tFolder) -- les sous-dossiers
        end repeat
    end tell
end remplaceAliasParOriginal

[zerod]

c'est gentil ca

j'avais mis en oeuvre cette méthode :

dans le finder rechercher tous les fichiers de type Alias
et lancer ce script après avoir fait cmd A :

Code

tell application "Finder" to repeat with a_alias in (get selection)
    try
        set f to original item of a_alias
        move f to container of a_alias with replacing
        delete a_alias
    end try
end repeat

La tienne est plus élégante merci beaucoup

edit : à un bémol quand même, le "(choose folder)" ne permet pas de rentrer dans le dossier iPhoto Library

Ce message a été modifié par zerod - 27 Apr 2011, 00:21.

[Guest_EricaL**_*]

edit : à un bémol quand même, le "(choose folder)" ne permet pas de rentrer dans le dossier iPhoto Library

Oui, c'est qu'il n'est pas considéré comme un dossier, car on ne peut pas voir son contenu par double clic.

Mais, c'est possible par (choose file)

Code

choose file with prompt "Sélectionnez un fichier 'iPhoto Library'" default location (path to pictures folder) without invisibles
set tFolder to ((the result as string) & "Originals") as alias
remplaceAliasParOriginal((tFolder) as list)

Dans cet exemple, c'est dans le dossier "Originals" que la recherche se fera, car c'est seulement dans ce dossier qu'il y a des alias .


Édition :

Si c'est pour iPhoto :
Voici la fonction qui renomme l'original selon le nom de l'alias, sinon iPhoto ne retrouvera pas la photo, si vous avez modifié le nom du fichier original.

Code

on remplaceAliasParOriginal(thesefolders)
    tell application "Finder"
        repeat with tFolder in thesefolders
            repeat with thisAlias in (get alias files of tFolder)
                set tName to name of thisAlias
                try
                    set tFile to duplicate (get original item of thisAlias) to tFolder with replacing
                    if (get name of tFile) is not tName then
                        delete thisAlias
                        set name of tFile to tName
                    end if
                end try
            end repeat
            my remplaceAliasParOriginal(get folders of tFolder) -- les sous-dossiers
        end repeat
    end tell
end remplaceAliasParOriginal

Ce message a été modifié par EricaL** - 27 Apr 2011, 05:17.