affichage des heures d'envoi des mails via AppleScript

[davdenice]

Bonjour,
Je cherche un script qui pourrait enregistrer tous les destinataires et les objets de mails écrits après 20h00 dans un fichiers .txt
Je bidouille un peu Applescript depuis peu, à part démarrer l'application Mail, je ne sais pas faire grand chose...
Merci pour votre aide.

[Zeltron54]

Je t'ai réécris le script, en évitant de l'écrire ligne par ligne, mais en créant (comme PBell) un fichier "emails_envoyés.txt" sur le breau, puis en l'important dans numbers et le trier par date du plus récent au plus ancien si tu veux le contraire il faut remplacer "descending" par "ascending".
Ce script sera plus rapide.
Tu auras le fichier texte sur le bureau et une page dans numbers.

Code

display dialog "Nombre de jours pour la recherche ?" default answer "1095"
set MDate to (current date) - days * (text returned of result) -- défini hier comme date de recherche
display dialog "Début Heure de recherche ?" default answer "20"
set heurelimite to text returned of result
set monTexte to ""
set AppleScript's text item delimiters to {" "}

tell application "Mail"
    set maListe to (every message in sent mailbox whose date sent > MDate)
    repeat with unMessage in maListe
        set maDate to date sent of unMessage
        if hours of maDate ≥ heurelimite then
            set mesDestinataires to (address of recipients of unMessage) as rich text
            set Ladate to (short date string of maDate)
            set madatetexte to maDate as string
            set heure to last text item of madatetexte
            set lejour to text item 1 of madatetexte
            set objet to subject of unMessage
            
            set monTexte to monTexte & lejour & tab & Ladate & tab & heure & tab & objet & tab & mesDestinataires & tab & return
        end if
    end repeat
end tell

set Fichier_Log to (((path to desktop) as text) & "emails_envoyés.txt")
try
    do shell script "touch " & (quoted form of (POSIX path of Fichier_Log))
    do shell script "echo " & (quoted form of monTexte) & " >> " & (quoted form of (POSIX path of Fichier_Log))
end try
set chemin to (path to desktop folder as text) & "emails_envoyés.txt" as alias
tell application "Numbers"
    activate
    open chemin
    tell the first table of the active sheet of document 1
                set format of column "B" to date and time
        sort by column "b" direction descending --in rows LaSelection
    end tell
end tell

tell application "Finder"
    activate
    (display dialog ("waouou ... Ca y est c'est fait !") buttons {"Salut !"})
end tell

Ce message a été modifié par Zeltron54 - 27 Oct 2022, 14:32.

[davdenice]

Je t'ai réécris le script, en évitant de l'écrire ligne par ligne, mais en créant (comme PBell) un fichier "emails_envoyés.txt" sur le breau, puis en l'important dans numbers et le trier par date du plus récent au plus ancien si tu veux le contraire il faut remplacer "descending" par "ascending".
Ce script sera plus rapide.
Tu auras le fichier texte sur le bureau et une page dans numbers.

Code

display dialog "Nombre de jours pour la recherche ?" default answer "1095"
set MDate to (current date) - days * (text returned of result) -- défini hier comme date de recherche
display dialog "Début Heure de recherche ?" default answer "20"
set heurelimite to text returned of result
set monTexte to ""
set AppleScript's text item delimiters to {" "}

tell application "Mail"
    set maListe to (every message in sent mailbox whose date sent > MDate)
    repeat with unMessage in maListe
        set maDate to date sent of unMessage
        if hours of maDate ≥ heurelimite then
            set mesDestinataires to (address of recipients of unMessage) as rich text
            set Ladate to (short date string of maDate)
            set madatetexte to maDate as string
            set heure to last text item of madatetexte
            set lejour to text item 1 of madatetexte
            set objet to subject of unMessage
            
            set monTexte to monTexte & lejour & tab & Ladate & tab & heure & tab & objet & tab & mesDestinataires & tab & return
        end if
    end repeat
end tell

set Fichier_Log to (((path to desktop) as text) & "emails_envoyés.txt")
try
    do shell script "touch " & (quoted form of (POSIX path of Fichier_Log))
    do shell script "echo " & (quoted form of monTexte) & " >> " & (quoted form of (POSIX path of Fichier_Log))
end try
set chemin to (path to desktop folder as text) & "emails_envoyés.txt" as alias
tell application "Numbers"
    activate
    open chemin
    tell the first table of the active sheet of document 1
                set format of column "B" to date and time
        sort by column "b" direction descending --in rows LaSelection
    end tell
end tell

tell application "Finder"
    activate
    (display dialog ("waouou ... Ca y est c'est fait !") buttons {"Salut !"})
end tell

Merci beaucoup pour ce script ! c'est top !
Là je télécharge 15 Go de mails, heureusement que j'ai la fibre, et hâte de tester tout ça !