affichage des heures d'envoi des mails via AppleScript

[davdenice]

Bonjour,
Je cherche un script qui pourrait enregistrer tous les destinataires et les objets de mails écrits après 20h00 dans un fichiers .txt
Je bidouille un peu Applescript depuis peu, à part démarrer l'application Mail, je ne sais pas faire grand chose...
Merci pour votre aide.

[Zeltron54]

Bonjour,
Au vu de toutes tes demandes, j'ai fait un script qui te demande le nombre de jours et l'heure limite, puis qui ouvre "Numbers" qui met le résultat dans une feuille et à la fin qui tri par date

Cela pourra te donner des idées pour le faire
Tu auras le choix entre excel et numbers...

Code

display dialog "Nombre de jours pour la recherche ?" default answer "1095"
set MDate to (current date) - days * (text returned of result) -- défini date de recherche
display dialog "Début Heure de recherche ?" default answer "20"
set heurelimite to text returned of result
set monTexte to ""
set AppleScript's text item delimiters to {" "}
tell application "Numbers"
    activate
    set newClasseur to make new document at front
    tell the first table of the active sheet of document 1
        set the value of cell "a1" to "Le jour"
        set the value of cell "b1" to "La date"
        set the value of cell "c1" to "Heure envoi"
        set the value of cell "D1" to "Objet"
        set the value of cell "e1" to "Le destinataire"
    end tell
end tell
set ligne to 2
tell application "Mail"
    set maListe to (every message in sent mailbox whose date sent > MDate)
    repeat with unMessage in maListe
        set maDate to date sent of unMessage
        if hours of maDate ≥ heurelimite then
            set heure to hours of maDate
            set mesDestinataires to (address of recipients of unMessage) as rich text
            set ladate to (short date string of maDate)
            set madatetexte to maDate as string
            set lejour to text item 1 of madatetexte
            set objet to subject of unMessage
            
            tell application "Numbers"
                activate
                tell the first table of the active sheet of document 1
                    set the value of cell ("a" & ligne) to lejour
                    set the value of cell ("b" & ligne) to ladate
                    set the value of cell ("c" & ligne) to heure
                    set the value of cell ("d" & ligne) to objet
                    set the value of cell ("e" & ligne) to mesDestinataires
                    make new row
                end tell
                
            end tell
            set ligne to ligne + 1
            
        end if
    end repeat
end tell

tell application "Numbers"
    activate
    tell the first table of the active sheet of document 1
        sort by column "b" direction descending --in rows LaSelection
    end tell
end tell
tell application "Finder"
    activate
    (display dialog ("waouou ... Ca y est c'est fait !") buttons {"Salut !"})
end tell