Automatisation : ouverture et tri de fichiers si endommagé [Résolu]

[zorkwolf]

Bonjour tout le monde,

Tout d'abord, je précise que je n'y connais absolument rien en automatisation, scripts, etc. et que je ne connais donc pas du tout les logiciels/outils qui me permettraient de faire ce que je souhaite faire. Je connais Automator de nom et qui a l'air très simple d'utilisation, mais à première vue, il ne m'aidera pas de le cas présent.
Je cherche donc une autre solution mais j'aurais besoin d'un coup de pouce pour trouver l'outil qui m'aidera à régler mon problème.

Pour résumer :
J'aimerais automatiser le tri de 18000 fichiers .ALS (fichiers Ableton Live) potentiellement endommagés. Si le logiciel signale le fichier comme étant endommagé, alors il est transféré dans un autre dossier. Sinon, rien n'est fait.

Le contexte :
J'ai fait une mise à jour de mon OS en clean install. J'ai sauvegarder les fichiers que je souhaitais sauver par un habile copié-collé (oui, je n'ai pas utilisé Time Machine, que j'utilise habituellement, pour des raisons indépendantes de Time Machine en lui-même ). Finder m'a proposé de fusionner certains dossiers, mais je me suis rendu compte que ça n'avait pas fonctionné comme je m'y attendais et malheureusement, je n'ai pas pris la peine de vérifier avant de formater mon disque dur.
Je tente une récupération avec Disk Drill. Parmi les fichiers que je souhaite récupérer, il y a des fichiers .ALS qui sont utilisés par le logiciel de MAO Ableton Live. Disk Drill en a trouvé 18000 alors qu'à la base, je devais en avoir une 100 aine au maximum. Je teste les 50 premiers fichiers, à l'ouverture, Ableton Live me les signalent tous comme étant endommagés. L'opération est fastidieuse et j'aimerais pouvoir automatiser la tâche.

Ce que je souhaite faire pour chaque fichier :
1- Ouvrir le fichier avec Ableton Live.
2- a- A l'ouverture, si le fichier est endommagé, Ableton Live le signale par le message suivant :

2- b- Sinon le fichier s'ouvre normalement.
3- a- Si le fichier est signalé comme étant endommagé, le fichier est transféré vers un dossier.
3- b- Si le fichier est ouvert correctement, rien n'est fait.

Si vous avez une autre méthode à proposer, je suis totalement preneur !!

J'allais poster dans la section "Technologies Apple" mais j'ai l'impression que ça correspond mieux ici. N'hésitez pas à me dire si je dois changer le post de section.

Merci d'avance pour vos retours,

zorkwolf

Ce message a été modifié par zorkwolf - 4 Apr 2020, 12:19.

[KOENIG Yvan]

Merci pour le retour.

Ableton n'est pas compatible avec AppleScript ce qui m'a obligé à avoir recours au GUI scripting qui émule les actions effectuées manuellement.

Problème, quand on demande ce que contient une fenêtre la réponse est une magnifique liste vide.
Du coup, vu que je récupérais une fenêtre standard et une fenêtre dialogue, j'ai considéré que ce dialogue signifiait la corruption du document testé.
Ne connaissant rien à la dite application, je ne sais comment elle se comporte en présence d'un fichier correct.

Pourriez-vous me faire parvenir un fichier ALS en bon état à l'adresse <koenigyan (AT) mac (POINT) com> ?
Ça me permettrai de voir comment se comporte l'appli en fonction d'un fichier correct et éventuellement coder un autre mode d'identification basé sur une éventuelle signature présente au début des fichiers.

Vérification faite, c'est plutôt le contraire de ce que j'indiquais. Mieux vaut utiliser les balises CODE (bouton ) pour éviter les coupures intempestives.
L'édition ne change rien.

Test de passage à la ligne :
Balises CODE

Code

set aBundle to aBundle & "Frameworks:ApplicationServices.framework:Versions:Current:Frameworks:HIServices.framework:"

Balises CODEBOX

CODE

set aBundle to aBundle & "Frameworks:ApplicationServices.framework:Versions:Current:Frameworks:HIServ
ices.framework:"

Merci.
Je n'avais pas prêté attention à la présence du bouton dont l'icône reproduit quasiment celle d'Applescript.

[baron]

[…] à l'adresse <koenigyan (AT) mac (POINT) com>

Je soupçonne qu'il faut ajouter un v entre y et an dans l'adresse indiquée…

[KOENIG Yvan]

[…] à l'adresse <koenigyan (AT) mac (POINT) com>

Je soupçonne qu'il faut ajouter un v entre y et an dans l'adresse indiquée…

Merci

Elle est bien bonne, voilà que je ne sais plus taper mon prénom

Ayant reçu le fichier exemple j'ai pu améliorer le script ce qui va me permettre de tester les balises

Code

[code]----------------------------------------------------------------
use AppleScript version "2.5"
use framework "Foundation"
use scripting additions

-- Yvan KOENIG (VALLAURIS, France) lundi 6 avril 2020  14:25:22

----------------------------------------------------------------

property |⌘| : a reference to current application

my Germaine()

on Germaine()
    set ableton to ((path to applications folder as string) & "Ableton Live 10 Trial.app:") as «class furl» -- Éditer le nom de l'application
    set p2d to path to desktop
    set sourceFolder to (choose folder "Sélectionner le dossier à analyser" default location p2d) as string
    set junkFolder to (choose folder "Sélectionner le dossier où ranger les corrompus" default location p2d) as string -- Édité pour ne plus utiliser un dossier qui peut ne pas exister
    try
        set aBundle to ((path to library folder from system domain as string) & "Frameworks:ApplicationServices.framework:Versions:Current:Frameworks:HIServices.framework:") as «class furl»
        set red_loc to localized string "Label_Name_6" from table "Labels" in bundle aBundle -- récupère la chaîne locale pour "Red"
    on error
        set red_loc to "rouge" -- version française du nom de couleur
    end try
    
    set fileManager to a reference to |⌘|'s NSFileManager's defaultManager()
    
    set skipsPackageDescendants to |⌘|'s NSDirectoryEnumerationSkipsPackageDescendants as integer --> 2
    set skipsHiddenFiles to |⌘|'s NSDirectoryEnumerationSkipsHiddenFiles as integer --> 4
    set theOptions to skipsPackageDescendants + skipsHiddenFiles
    
    set NSURLIsDirectoryKey to |⌘|'s NSURLIsDirectoryKey
    set keysToRequest to {NSURLIsDirectoryKey}
    
    tell me to display notification "Commence à scanner le dossier" & linefeed & (current date)
    
    set theURL to (|⌘|'s NSArray's arrayWithObject:(sourceFolder as «class furl»))'s firstObject()
    -- test désactivé parce que, étant défini par Choose folder, le dossier existe
    -- if (theURL's checkResourceIsReachableAndReturnError:(missing value)) as boolean is false then error "The folder “" & sourceFolder & "” isn't available."
    set junkURL to (|⌘|'s NSArray's arrayWithObject:(junkFolder as «class furl»))'s firstObject()
    -- test désactivé parce que, étant défini par Choose folder, le dossier existe
    -- if (junkURL's checkResourceIsReachableAndReturnError:(missing value)) as boolean is false then error "The folder “" & junkFolder & "” isn't available."
    
    set allURLs to (fileManager's enumeratorAtURL:theURL includingPropertiesForKeys:keysToRequest options:theOptions errorHandler:(missing value))'s allObjects()
    if allURLs is equal to missing value then error (theError's localizedDescription() as text)
    
    tell me to display notification "trouvé " & (count allURLs) & " URLs." & linefeed & (current date)
    
    set theFormat to "(self.path ENDSWITH[c] '.ALS')" -- pour lister les fichiers dont le nom se termine par ".ALS"
    set thePredicate to |⌘|'s NSPredicate's predicateWithFormat:theFormat
    set fichiersALS to (allURLs's filteredArrayUsingPredicate:thePredicate)
    tell me to display notification "trouvé " & (count fichiersALS) & " fichiers .ALS." & linefeed & (current date)
    repeat with aURL in fichiersALS
        set aFurl to aURL as «class furl»
        tell application "Finder" to open aFurl using ableton
        
        tell application "System Events"
            repeat -- Attends que l'application soit ouverte
                if exists process "Live" then exit repeat
                delay 0.1
            end repeat
            tell process "Live"
                set frontmost to true -- Assure que le process va pouvoir exécuter les actions
                repeat
                    set nbWindows to count windows
                    if nbWindows > 0 then exit repeat
                    delay 0.1
                end repeat
                set theSubroles to subrole of windows
                --> {"AXDialog", "AXUnknown", "AXUnknown"} -- pour un document corrompu
                --> {"AXStandardWindow", "AXUnknown"} -- pour un document sain
                if theSubroles contains "AXDialog" then
                    -- attribue un double tag
                    set {theResult, theError} to (aURL's setResourceValue:{red_loc, "ALS corrompu"} forKey:(current application's NSURLTagNamesKey) |error|:(specifier))
                    -- déplace le fichier
                    (my moveFromURL:aURL toFolder:junkURL)
                else
                    -- fichier valide
                end if
                -- Arrive ici dans les deux cas pour fermer les fenêtres
                try -- En principe on ne devrait pas générer d'erreur mais je joue la sécurité
                    set nbWindows to count windows
                    repeat 5 times -- En principe, nbWindows times suffirait mais je joue la sécurité
                        if not (exists window 1) then exit repeat -- plus propre, ne génère pas de message d'erreur
                        tell window 1
                            if exists button 1 then
                                click button 1
                            else
                                keystroke return
                            end if
                        end tell
                        delay 0.2
                    end repeat
                on error errmsg number errNbr
                    -- tell application "Finder" to display dialog errmsg -- "Erreur dans System Events : Il est impossible d’obtenir process \"Live\"."
                end try
            end tell -- process "Live"
        end tell -- "System Events"…
    end repeat
    
end Germaine

#=====

on moveFromURL:sourceURL toFolder:junkURL
    set theFileManager to |⌘|'s NSFileManager's |defaultManager|()
    set origName to sourceURL's |lastPathComponent|() as string --> "trucmuche.ALS"
    tell (current date) to set stamp to (((its year) * 10000 + (its month) * 100 + (its day)) as text) & "_" & text 2 thru -1 of ((1000000 + (its hours) * 10000 + (its minutes) * 100 + (its seconds)) as text)
    -- par sécurité, intercale date-time pour éviter doublons
    set destName to (text 1 thru -5 of origName) & "_" & stamp & ".ALS" --> "trucmuche_20200404_154332.ALS"
    set destinationURL to junkURL's URLByAppendingPathComponent:destName
    set {theResult, theError} to (theFileManager's moveItemAtURL:sourceURL toURL:destinationURL |error|:(reference))
end moveFromURL:toFolder:

#=====

Bien entendu vous pouvez réutiliser le code recherchant les fichiers pour d'autres tâches.

Les instructions ASObjC sont verbeuses mais je préfère çà aux incantations "do shell script"