Trier des photos avec Applescript, Portrait ou Paysage

[MacMame]

Bonjour,


Je possède un dossier images/ dans lequelle il y à des des sous dossier sur plus de 10 niveaux, dans presque chaque sous dossier, il y à des photos; je souhaiterais développer un applescript qui me scan le dossier image (en recursive donc) et qui affecte par exemple un tag vert pour les photos portrait et un tag rouge pour les photos paysage.

Vous pensez que c'est possible ? tout en gardant bien sur les sous-sous dossier à leurs place.

Merci pour votre aide.

[Zeltron54]

Bonjour,

Voilà le script qui fait le job, et à la fin déplace tous les fichiers dans un dossier "PHOTO_TRAITEES"

La préparation:
1- créer un dossier vide Nom : par exemple "Photo_a_traiter"
2- créer un dossier sur le bureau qui recevra le résultat après traitement : nom du dossier "PHOTO_TRAITEES"
3- Enregistrer le script dans Utilisateurs —> « le nom d’utilisateurs » —> Bibliothèque —> Scripts —> Folder Action Scripts Si les dossiers « scripts » et ou « Folder Action Scripts » n’existent pas il faut les créer.
4- Faire un clic droit sur le dossier "Photo_a_traiter" —> service —> Configuration des actions de dossier… - Dans le fenêtre qui s’ouvre (choisir le script à joindre:) sélectionner le script, cocher la case "Activer les actions de dossier"

Tous dossiers et ou fichiers qui seront déposer sur le dossier "Photo_a_traiter" sera traité par tes scripts photoshop puis seront déplacés dans le dossier "PHOTO_TRAITEES"
Le dossier "Photo_a_traiter" sera donc toujours vide en attente.

Si tout fonctionne correctement on regardera pour ajouter l'envoi d'un mail.

Code

on adding folder items to Mon_Dossier after receiving Liste_Fichiers
    my inspecter(Mon_Dossier)
    
    
    
    tell application "Finder"
        set destination to Mon_Dossier & ":PHOTO_TRAITEES" as string
        set theFiles to entire contents of Mon_Dossier
        move theFiles to destination
        
        (display dialog ("waouou ... Ca y est c'est fait !") buttons {"Salut !"})
    end tell
    
end adding folder items to
on inspecter(source)
    tell application "Finder"
        -- traitement des fichiers :
        
        set les_fichiers to files of source
        repeat with chaque_fichier in les_fichiers
            -- traitement d'un fichier
            tell application "Finder"
                set lefichier to chaque_fichier
                set extension_a_traiter to {"jpg", "png", "psd"} -- Liste des extensions à traiter
                set nom to name of chaque_fichier
                set extens to document file nom in source --recupere l extension du fichier
                set lextension to name extension of extens
                
                if lextension is in extension_a_traiter then
                    tell application "Image Events"
                        set b to open (lefichier as alias)
                        set {wid, hit} to b's dimensions
                        close b
                    end tell
                    set monfichier to lefichier as string
                    if wid < hit then
                        set tCollection to "photos-portrait"
                        tell application "Adobe Photoshop CC 2015.5" -- à corriger avec ta version
                            open file monfichier
                            do action "REDIM" from tCollection -- le script sauvegarde et ferme l'image après traitement
                            close saving no
                        end tell
                    else
                        
                        set tCollection to "photos-paysage"
                        tell application "Adobe Photoshop CC 2015.5" -- à corriger avec ta version
                            open file monfichier
                            do action "REDIM" from tCollection -- le script sauvegarde et ferme l'image après traitement
                            close saving no
                        end tell
                    end if
                end if
            end tell
        end repeat
        -- traitement des dossiers :
        set les_dossiers to folders of source
        repeat with chaque_dossier in les_dossiers
            -- traitement d'un dossier
            my inspecter(chaque_dossier)
        end repeat
    end tell
end inspecter

Ce message a été modifié par Zeltron54 - 22 Apr 2018, 20:51.