Bureau qui se désorganise, toutes les icones se groupent à droite de l'écran

[jacbuz]

Bonjour à tous... J'ai un problème, et je ne suis pas le seul à l'avoir.
Le matin, à l'ouverture de mon iMac (27"), toutes les icones présentes sur le bureau, ne gardent plus la place initiale donnée la veille, mais se regroupent dans n'importe quel ordre, sur le côté droit de l'écran.
C'est fastidieux, désagréable, voire énervant.
Quelqu'un connaît-il : la raison ? et surtout la solution ?
Merci de votre aide.

JB OS 10.6.2

[anael]

sucellus à mis à jour son code AppleScript (qui est même commenté)

Je l'ai testé sous Snow Leopard 10.6.2, il fonctionne sans problème ! Le voici ci-dessous.

C'est maintenant une solution relativement pratique à la désorganisation inopinée des icônes de bureau.

Un grand merci !

J'ai écrit un nouveau code, qui fait la même chose mais utilisable en application à placer au démarrage.

Code

-- Rangement des icônes sur le bureau
-- Légal Jean Louis (créé le 6 Novembre 2009 modifié 24 Février 2010)
-- Version 0.1.1 ß Testé avec Leopard 10.5.8

-- ATENTION le déplacement des icônes sur le bureau n'est accepté que suivant le réglage de la grille

-- \\\ VARIABLES IMPORTANTES POUR CE CODE /// --

property theList : missing value -- Mémoire
property listCtrl : missing value -- Mémoire de contrôle
property mem : false -- Pour affichage des fenêtres d'alertes (True OUI, False NON)

-- \\\ PREMIÈRE UTILISATION /// --

if theList is missing value then -- La mémoire est vide
    display dialog "Voulez-vous sauvegarder vos icônes à leur emplacement actuel ?" buttons {"Annuler", "Sauvegarder"} default button 2 with title "Sauvegarde des positions d'icônes"
    if (button returned of result) is "Annuler" then return -- Bouton Annuler, alors on quitte
    -- Lecture et écriture des noms et positions des icônes sur le bureau dans la variable de mémoire
    tell application "Finder" to set theList to {name, desktop position} of items of desktop
    -- On quitte le code
    
else
    
    -- \\\ UTILISATIONS SUIVANTES /// --
    
    tell application "Finder"
        -- Lecture des noms et positions des icônes sur le bureau pour faire des contrôles
        set listCtrl to {name, desktop position} of items of desktop
        -- Contrôle si le contenue la liste en mémoire est plus petite que celui de la liste de contrôle
        if ((count (first item of theList)) as integer) < ((count (first item of listCtrl)) as integer) then set mem to true
        -- Contrôle que les 2 listes sont identiques (mêmes noms aux icônes)
        if (first item of theList) does not contain (first item of listCtrl) then set mem to true
        -- Range seulement les icônes mémorisées
        repeat with i from 1 to (count (first item of theList))
            try -- Pour éviter les erreurs si un nom n'existe pas lors du rangement
                set desktop position of item (item i of first item of theList) of desktop to (item i of second item of theList)
            end try
        end repeat
        -- Si on supprime des icônes sans ajouts d'autres sur le bureau, les suppriment de la mémoire
        if ((count (first item of theList)) as integer) > ((count (first item of listCtrl)) as integer) then
            -- Mémorisation de la nouvelle liste des icônes sur le bureau
            tell application "Finder" to set theList to {name, desktop position} of items of desktop
            set mem to false -- Suppression d'icônes sans ajouts, donc pas de fenêtre d'alerte
        end if
    end tell
end if

-- \\\ DES MODIFICATIONS DONC DES NOUVELLES ICÔNES /// --

-- Si l'on ajoute où remplace des icônes par d'autres (donc changement de noms)
if mem is true then
    tell me to activate -- Etre sur que cette fenêtre seras en premier plan sur le bureau
    display dialog "Différence avec les icônes en mémoire et les icônes trouvées sur le bureau." buttons {"Annuler", "Sauvegarder"} default button 2 with title "Sauvegarder les positions des icônes"
    if (button returned of result) is "Annuler" then return -- Bouton Annuler, alors on quitte
    -- Mémorisation des noms et positions des icônes sur le bureau
    tell application "Finder" to set theList to {name, desktop position} of items of desktop
    set {listCtrl, mem} to {theList, false} -- Initialisation des variables
end if

Comment créer une application avec ce code ?

Léopard = Copier-Coller ce code dans Applications/AppleScript/Éditeur de scripts
Snow Léopard = Copier-Coller ce code dans Applications/Utilitaires/AppleScript Editor
Bouton Compiler (si le texte prend des couleurs, c'est bon).

Bouton Exécuter [ou Compiler, et le code se colore]

Barre des menus Fichier/Enregistrer sous…
Donner un nom.
Choisir où enregistrer l'application.
Léopard = Format de fichier : Progiciel (pour être compatible PPC et intel).
Snow Léopard = Format de fichier : Application.
Si écran de démarrage coché alors le décocher.
Enregistrer

Ensuite, placer l'application dans les préférences de votre compte utilisateur, onglet "Ouverture" (bouton "+")

[sucellus]

Bonjour

Un oublie de ta part (les explications du fonctionnement du code (que je t'ai jamais donnée)).

Rangement des icônes

Rangement des icônes sur le bureau en mode manuel.
Mémorisation des noms et positions d'icônes sur le bureau.

Si aucune modification d'icônes sur le bureau, à la prochaine utilisation, les ranges et quitte.

Si suppression d'icônes sur le bureau, et nombre d'icônes en mémoire se retrouve supérieures a celles du bureau, mise à jour de la mémoire (donc suppression des icônes inutiles en mémoire).

Si le même nombre d'icônes sur le bureau, mais certaines ont été remplacées par d'autres alors demande de rangement et sauvegarde (si bouton Annuler non utilisé).

Si ajout d'icônes (nombre plus grand que celui en mémoire d'icônes) sur le bureau alors demande de rangement et sauvegarde (si bouton Annuler non utilisé).

Pour changer la position de toutes où certaines icônes, en ajouter une, mémorisez.

Ne déplacer les icônes pour changement de position des icônes mémorisées que la fenêtre d'alerte ouverte, car il place les icônes mémorisées a leurs places avant d'ouvrir la fenêtre.

Sauvegarder.

Il reste plus qu'a éliminer l'icône inutile (a la prochaine utilisation du code elle seras éliminée de la mémoire donc pas relancer le code juste pour la supprimer).

Ce code est alors plus pratique en ouverture au démarrage, si aucune modification range et quitte.

C'est un code provisoire, la prochaine version de Snow Léopard va corriger ce problème (où une suivante).

Code pratique en mode manuel, si pour des jeux vous changez de résolution, ce code replace les icônes où vous les avez mémorisée.

@+

[robertito]

Bonjour

Un oublie de ta part (les explications du fonctionnement du code (que je t'ai jamais donnée)).

Rangement des icônes

Rangement des icônes sur le bureau en mode manuel.
Mémorisation des noms et positions d'icônes sur le bureau.

Si aucune modification d'icônes sur le bureau, à la prochaine utilisation, les ranges et quitte.

Si suppression d'icônes sur le bureau, et nombre d'icônes en mémoire se retrouve supérieures a celles du bureau, mise à jour de la mémoire (donc suppression des icônes inutiles en mémoire).

Si le même nombre d'icônes sur le bureau, mais certaines ont été remplacées par d'autres alors demande de rangement et sauvegarde (si bouton Annuler non utilisé).

Si ajout d'icônes (nombre plus grand que celui en mémoire d'icônes) sur le bureau alors demande de rangement et sauvegarde (si bouton Annuler non utilisé).

Pour changer la position de toutes où certaines icônes, en ajouter une, mémorisez.

Ne déplacer les icônes pour changement de position des icônes mémorisées que la fenêtre d'alerte ouverte, car il place les icônes mémorisées a leurs places avant d'ouvrir la fenêtre.

Sauvegarder.

Il reste plus qu'a éliminer l'icône inutile (a la prochaine utilisation du code elle seras éliminée de la mémoire donc pas relancer le code juste pour la supprimer).

Ce code est alors plus pratique en ouverture au démarrage, si aucune modification range et quitte.

C'est un code provisoire, la prochaine version de Snow Léopard va corriger ce problème (où une suivante).

Code pratique en mode manuel, si pour des jeux vous changez de résolution, ce code replace les icônes où vous les avez mémorisée.

@+

Merci pour ce script qui m'aide beaucoup a replacer les icônes qui changeait à chaque fois que je changeait la résolution de mon écran. Je suis très impressionné par vos qualités de programmeur AppleScript.