Vider la corbeille d'un disque amovible, et seulement celle de ce disque

[jojomail]

Bonjour

est il possible de ne vider que la corbeille d'un disque amovible (clé usb, disque dur externe, image disque...) sous MacOSX ? Car à part aller chercher le fichier .Trashe du dit support amovible, je ne vois pas de solution.

Or il est souvent nécessaire de pouvoir récupérer de l'espace sur un support amovible sans vouloir pour autant vider la corbeille du disque dur principal !

Une solution ?

[jojomail]

@macuserfr : merci pour les liens trés trés instructifs et utiles ! SuperEmptyTrash va troner sur mon dock, a coté de la corbeille normale !

[Guest_EricaL**_*]

Bonsoir,

Je trouve que l'application SuperEmptyTrash n'est pas très pratique :
1— il faut le lancer, et choisir un volume
2— On ne peut pas sélectionner plusieurs volumes, c’est tous les volumes ou un seul volume.
3— Il faut taper un mot de passe.

Alors que ce serait plus simple par glisser/déposer.
Et aucun besoin d'un mot de passe pour vider notre dossier corbeille, sauf en cas d'anomalie, ce qui est très rare.

Pour ceux qui sont intéressés par un script qui vide le dossier ".Trashes/50x/" des volumes déposés sur l'application :

Copier et coller ce code dans la fenêtre de l'application "Editeur de script".

Code

on open these_volumes
    set t_id to user ID of (system info)
    repeat with i in these_volumes
        if (kind of (info for i without size)) is "Volume" then -- c'est un volume
            set d to (POSIX path of i) & ".Trashes/" & t_id
            do shell script "/bin/rm -Rf  " & (quoted form of d) & "/*"
        end if
    end repeat
end open

Enregistre-le au format "Progiciel".

Après, glisser et déposer un ou des volumes sur l'application.

Editer :
Pour ceux qui veulent un dialogue pour confirmer que vous voulez bien vider la corbeille, voici le script :

Code

on open these_volumes
    set t_id to user ID of (system info)
    set Maliste to {}
    set t to ""
    repeat with i in these_volumes
        if (kind of (info for i without size)) is "Volume" then -- c'est un volume
            set t to t & (i as string) & return
            set end of Maliste to (POSIX path of i) & ".Trashes/" & t_id
        end if
    end repeat
    
    if t is not "" then
        display dialog "Voulez-vous vraiment vider les corbeilles de ces volumes" & return & return & t ¬
            buttons {"Non", "Oui"} cancel button "Non" default button "Non"
        repeat with i in Maliste
            do shell script "/bin/rm -Rf  " & (quoted form of i) & "/*"
        end repeat
    end if
end open

Ce message a été modifié par EricaL** - 21 Jul 2009, 16:35.