HELP! La bidouille iTunes pour les noms de groupes ne marche plus!

[zteph]

Bonsoir à tous,

Je viens de faire l'update de iTunes, et, comme à chaque nouvelle version, je dois me taper la bidouille consistant à ouvrir le fichier localizable.strings de l'application pour que iTunes reconnaisse les noms de groupe anglophones et que par exemple, elle classe "The Beatles" à la lettre B et non à la lettre T...

Or la bidouille semble ne pas fonctionner... J'ai fait exactement la même chose que d'habitude et là on dirait que iTunes ne veut rien savoir. LEs fameuses lignes de code supplémentaires sont bien sauvées avec le fichier, mais il n'en tient pas compte...

Est-ce que quelqu'un a remarqué le même problème?


Merci de me tenir au courant

[m00n]

Tout d'abord, je remercie JackJr300 pour son script géant.

Je me suis permis de le modifier pour le rendre plus convivial. Je vous en fais profiter :

CODE

tell application "iTunes"
    if (get version) as string < "7.1" then error "Votre Version de iTunes est trop ancienne."
    
    set message to "Ce script supprime les articles (The, Le, La, Les, Los) des noms de groupes dans l'onglet tri des informations de morceaux dans la playlist sélectionnée.  
Il ne tient pas compte de la casse.
Le nom réel reste inchangé.  
        
Voulez-vous continuer ?"
    set tempVar to display dialog message buttons {"Oui", "Non"} default button 2
    set boutonAppuye to button returned of tempVar
    
    if boutonAppuye = "oui" then
        
        tell (get view of front browser window) to if special kind is not in {Podcasts, Movies, Audiobooks, TV Shows, Videos} then
            repeat with t_text in {"The ", "Le ", "Les ", "La ", "L'", "Los"}
                set L to (length of t_text) + 1
                repeat with t_track in (get tracks whose artist starts with t_text)
                    tell t_track to set sort artist to text L thru -1 of (get artist)
                end repeat
            end repeat
        end if
        
        beep
        set message to "Opération réussie !"
        display dialog message buttons {"Ok"}
        
    end if
end tell

Voilà.