Graphic Converter réduira la taille des photos converties par Transfert d'images, Réactions à la publication du 01/05/2020

[Lionel]

Philippe Bonnaure nous informe que la dernière version beta de Graphic Converter et bientôt la version 11.2 pourront régler le problème de taille trop importante des fichiers JPEG provoqué par un bug du logiciel Transfert d'image.

Lien vers le billet original

[KOENIG Yvan]

Je rappelle que je vous ai communiqué un script qui effectue le nettoyage sans outil supplémentaire.

https://forum.macbidouille.com/index.php?sh...p;#entry4329239

[alex54]

C'est fou, en ce moment l'actualité d'apple, c'est BUG, Perte compatibilité, Faille 0-day, Panne apple pay... Ca se voit l'effet "think différent" ! Acheter plus cher pour être emmerder plus !

[baron]

Je rappelle que je vous ai communiqué un script qui effectue le nettoyage sans outil supplémentaire.

https://forum.macbidouille.com/index.php?sh...p;#entry4329239

Le lien précis est : https://forum.macbidouille.com/index.php?s=...t&p=4329027

[Anozer]

Quelqu’un a essayé avec ImageOptim ? C’est un petit soft open source très sympa.
https://imageoptim.com/mac

[Fafnir]

autre sujet
je viens de voir à la tv que les magasins vendant de l'alcool sont désormais équipé de détecteur pour mesurer à distance la température des clients:
https://ca.hikvision.com/fr

[malloc]

Pour ceux qui souhaitent j’ai fait un petit soft qui traque de façon récursive à partir d’un dossier cible tous les JPEG avec des 0 à la fin et les enlève.

J’ai gagné 300Mo sur mon disque, le bug devait être la depuis un moment.

Si ça vous intéresse, envoyez moi un MP!

[Little Brother]

Cela concenerait donc les photos intégrées à iPhotos/Photos ?
Si oui, comment fait on pour réduire la taille de la photothèque ?

[KOENIG Yvan]

Bonsoir

Pour Photos vous pouvez utiliser :

Code

use AppleScript version "2.5"
use framework "Foundation"
use scripting additions

property |⌘| : a reference to current application

set theLib to ((path to pictures folder) as string) & "Photos Library.photoslibrary:Masters:"

set theURL to (|⌘|'s NSArray's arrayWithObject:(theLib as «class furl»))'s firstObject()

set theManager to |⌘|'s NSFileManager's defaultManager()
set skipSubdirectoryDescendants to |⌘|'s NSDirectoryEnumerationSkipsSubdirectoryDescendants as integer --> 1
set skipHidden to |⌘|'s NSDirectoryEnumerationSkipsHiddenFiles as integer --> 4

set allURLs to (theManager's enumeratorAtURL:theURL includingPropertiesForKeys:{} options:skipHidden errorHandler:(missing value))'s allObjects()
set theFormat to "(self.pathExtension =[c] 'jpg') OR (self.pathExtension =[c] 'jpeg')"
set thePredicate to |⌘|'s NSPredicate's predicateWithFormat:theFormat
set jpegURLs to (allURLs's filteredArrayUsingPredicate:thePredicate)

repeat with anURL in jpegURLs
    my removeGarbage(anURL)
end repeat

on removeGarbage(theFile)
    -- handler written by Shane Stanley on 2020/04/30
    --search for FFD900
    set b64String to "/9kA" -- FFD900 in Base64
    set b64Data to current application's NSData's alloc()'s initWithBase64EncodedString:b64String options:0
    set theData to current application's NSData's dataWithContentsOfURL:theFile
    set dataLen to theData's |length|()
    set theRange to theData's rangeOfData:b64Data options:(current application's NSDataSearchBackwards) range:{0, dataLen}
    if |length| of theRange = 3 then
        -- make sure only nulls after it by making base64 string of the rest, then looking for other than A or = in it
        set maxRange to current application's NSMaxRange(theRange)
        set endData to theData's subdataWithRange:{maxRange + 1, dataLen - maxRange - 1}
        set endB64 to (endData's base64EncodedStringWithOptions:0)
        set newRange to endB64's rangeOfString:"[^A=]" options:(current application's NSRegularExpressionSearch)
        if |length| of newRange is 0 then
            -- we know it's only nulls
            set eof theFile to ((location of theRange) + 2)
        end if
    end if
end removeGarbage

Pour iPhoto il faudrait éditer l'instruction:

Code

set theLib to ((path to pictures folder) as string) & "Photos Library.photoslibrary:Masters:"

mais malheureusement je ne connais pas le nom exact de la bibliothèque de cette application.

Comme mon précédent script celui-ci peut être enregistré en tant qu'application mais cette fois, seul le double-clic est utilisable.

[KOENIG Yvan]

Par sécurité effectuez une copie de la library avant d'appliquer mon script.
Je ne sais pas comment la structure réagit quand on modifie la longueur des fichiers.

[Little Brother]

Ok, merci Yvan, je testerai ça, après un clonage

[KOENIG Yvan]

Je pensais à une duplication de la library de Photos. Cloner le disque est un peu lourd pour ce qui nous concerne ici.

[fxn]

C'est fou, en ce moment l'actualité d'apple, c'est BUG, Perte compatibilité, Faille 0-day, Panne apple pay... Ca se voit l'effet "think différent" ! Acheter plus cher pour être emmerder plus !

bon là vous êtes quand même d'accord qu'il y a un petit problème d'instabilité mentale... on est pas loin du TOC

[alex54]

C'est fou, en ce moment l'actualité d'apple, c'est BUG, Perte compatibilité, Faille 0-day, Panne apple pay... Ca se voit l'effet "think différent" ! Acheter plus cher pour être emmerder plus !

bon là vous êtes quand même d'accord qu'il y a un petit problème d'instabilité mentale... on est pas loin du TOC

Commentaire typique des fanboys n'ayant pas enlever les kilo de merde dans chaque oeil ! Je les ai enlevé il y a un moment maintenant, jamais été peu emmerder par un OS où du matériel depuis que je suis passer chez Lenovo et windows 10.

Les dernière moutures apple sont livré avec leurs lots d'emmerde et de déconvenu dès la sortie du cartons, il n'y a qu'a voir le nombre de patch, mise à jour, soucis matérielle, entrave matérielle (T2) qui existe chez apple. La non réparabilité (tout soudé), les prix exorbitants pour du matérielle déjà dépasser à la mise en vente, les prix exorbitant des accéssoire (roulette du dernier mac pro).

J'ai été chez Apple pendant de longue année, et je n'en peux plus d'avoir un petit soucis merdique qui te pourrit la vie et la productivite, la goutte d'eau ça a été la réparation d'un macbook pro qui été fait par un porchio en apple store résultat machine irréparable soi-même par la suite. Le pas de vis niquer, soucis planqué par une quantité incroyable de colle pour faire tenir une vis de ventilateur jusqu'au jour ou cela n'a plus tenu et que la vis se barre et que je m'en rende compte, bien sure en apple store ca n'est pas eut et pas de solution a apporté car la machine déclaré obsolète par Apple -> ils n'ont plus de pièces)

Alors ton commentaire d'instabilité mentale tu te le gardes, mais mon observation ne date pas d'hier et plus le temps passe et plus la qualité du matos et des livrables chez apple BAISSE. Si tu ne le vois pas et qu'aveuglément tu continues a acheter du matos dans une boite qui ne pense qu'a une chose : LE FRIC c'est ton problème, mais le soucis mentale vient plutôt de ton côté qui ne reconnait même pas les problèmes qu'il y a chez Apple.

[malloc]

enlever les kilo de merde dans chaque oeil (...) jamais été peu emmerder par un OS où du matériel depuis que je suis passer chez Lenovo et windows 10.

Les dernière moutures apple sont livré avec leurs lots d'emmerde (...) petit soucis merdique qui te pourrit la vie et la productivite

Quand la forme est au service du fond, le forum devient un régal. Merci l'artiste.

[KOENIG Yvan]

Bonjour
Vous trouverez ci-dessous une version complétée de mon script.
Elle permet de sélectionner une source de fichiers jpegs qui peut éventuellement être un dossier standard.
Il sera peut-être nécessaire de modifier le dernier nom de dossier pour l'entrée "Dossier Masters de la photothèque iPhoto" car je n'ai pas eu accès à celle-ci. N'hésitez pas à me communiquer le nom exact.

Code

use AppleScript version "2.5"
use framework "Foundation"
use scripting additions

property |⌘| : a reference to current application

set source1 to "Photothèque Aperture complète"
set source2 to "Dossier Masters de la photothèque Aperture"
set source3 to "Photothèque Photos complète"
set source4 to "Dossier Masters de la photothèque Photos"
set source5 to "Photothèque iPhoto complète"
set source6 to "Dossier Masters de la photothèque iPhoto"
set source7 to "choose folder" -- Dialogue de sélection d'un dossier

set myChoice to (choose from list {source1, source2, source3, source4, source5, source6, source7} with prompt "Choisissez un dossier source")
if myChoice is false then error number -128
set myChoice to myChoice's item 1

if myChoice is source1 then
    set theLib to ((path to pictures folder) as string) & "Aperture Library.aplibrary:"
else if myChoice is source2 then
    set theLib to ((path to pictures folder) as string) & "Aperture Library.aplibrary:Masters:"
else if myChoice is source3 then
    set theLib to ((path to pictures folder) as string) & "Photos Library.photoslibrary:"
else if myChoice is source4 then
    set theLib to ((path to pictures folder) as string) & "Photos Library.photoslibrary:Masters:"
else if myChoice is source5 then
    set theLib to ((path to pictures folder) as string) & "Photos Library.photoslibrary:"
else if myChoice is source6 then
    set theLib to ((path to pictures folder) as string) & "Photos Library.photoslibrary:Masters:" -- vérifier le nom de la photothèque
else if myChoice is source7 then
    set theLib to choose folder -- Dossier à sélectionner
end if

set theURL to (|⌘|'s NSArray's arrayWithObject:(theLib as «class furl»))'s firstObject()

set theManager to |⌘|'s NSFileManager's defaultManager()
set skipSubdirectoryDescendants to |⌘|'s NSDirectoryEnumerationSkipsSubdirectoryDescendants as integer --> 1
set skipHidden to |⌘|'s NSDirectoryEnumerationSkipsHiddenFiles as integer --> 4

set allURLs to (theManager's enumeratorAtURL:theURL includingPropertiesForKeys:{} options:skipHidden errorHandler:(missing value))'s allObjects()
set theFormat to "(self.pathExtension =[c] 'jpg') OR (self.pathExtension =[c] 'jpeg')"
set thePredicate to |⌘|'s NSPredicate's predicateWithFormat:theFormat
set jpegURLs to (allURLs's filteredArrayUsingPredicate:thePredicate)

repeat with anURL in jpegURLs
    my removeGarbage(anURL)
end repeat

on removeGarbage(theFile)
    -- handler written by Shane Stanley on 2020/04/30
    --search for FFD900
    set b64String to "/9kA" -- FFD900 in Base64
    set b64Data to |⌘|'s NSData's alloc()'s initWithBase64EncodedString:b64String options:0
    set theData to |⌘|'s NSData's dataWithContentsOfURL:theFile
    set dataLen to theData's |length|()
    set theRange to theData's rangeOfData:b64Data options:(|⌘|'s NSDataSearchBackwards) range:{0, dataLen}
    if |length| of theRange = 3 then
        -- make sure only nulls after it by making base64 string of the rest, then looking for other than A or = in it
        set maxRange to |⌘|'s NSMaxRange(theRange)
        set endData to theData's subdataWithRange:{maxRange + 1, dataLen - maxRange - 1}
        set endB64 to (endData's base64EncodedStringWithOptions:0)
        set newRange to endB64's rangeOfString:"[^A=]" options:(|⌘|'s NSRegularExpressionSearch)
        if |length| of newRange is 0 then
            -- we know it's only nulls
            set eof theFile to ((location of theRange) + 2)
        end if
    end if
end removeGarbage

Ce message a été modifié par KOENIG Yvan - 5 May 2020, 13:43.