[AS] Récupérer des infos sur les artworks, Taille, chemin

[Brys]

Bonsoir

Tout est dans le titre.
Je souhaiterais obtenir les dimensions d'un artwork, sa taille et par la même occasion son chemin dans le Finder.
C'est impossible de s'y retrouver dans le dossier Album Artwork : aucun nom clair, une multitude de dossiers et sous-dossiers…
Et de toute façon comment tirer une quelconque information de ces .itc ?

Ce n'est eut être pas possible AS…

Ce message a été modifié par Brys - 28 Jun 2007, 18:29.

[Guest_JackJr300_*]

Bonjour

Ce n'est pas possible directement sans faire un nouveau fichier image.

Les fichiers ".itc" contiennent les images au format PNG, le nom du fichier est le (Persistent ID) de la bibliothèque et du fichier de référence de l'album, c'est possible d'extraire l'image de ces fichiers.

Pour le script, ça va dépendre de ce que tu veux faire..

----
Est ce que tu as vraiment besoin de savoir l'emplacement du fichier ".itc" ?
Parce qu'on peut extraire l'image à partir du (data of artwork of track xyz ), si l'illustration est déjà dans le morceau.
-----
_____
Si tu as besoin du fichier ".itc", il faut rechercher le fichier de référence de l'album, parce que iTunes ne garde dans son dossier "Album Artwork " qu'une seule image par album.
C'est possible sur Tiger en recherchant dans le fichier "iTunes Music Library.xml"
_____

[MRIC]

J'ai post le même type de question dans Itunes, personne n'a répondu ...

En fait apparemment il existe un osax qui permet de prendre le Data du artwork, pour le remettre en .jpg ou .png (après les autres questions, je sais pas ...)

[Guest_JackJr300_*]

J'ai post le même type de question dans Itunes, personne n'a répondu ...

En fait apparemment il existe un osax qui permet de prendre le Data du artwork, pour le remettre en .jpg ou .png (après les autres questions, je sais pas ...)

Désolé, je n'avais pas vu ton message dans iTunes.

Je ne sais pas s'il existe un osax, je n’en ai pas trouvé.

Mais ce script fait ça.

CODE

property temp_file : (path to temporary items as string) & "artwork_of_current_track.jpg"

try
    tell application "iTunes" to tell current track
        if exists artworks then
            my make_Image(data of artwork 1)
            ---- mettre ici le code pour afficher l'image temp_file
        else
            ---- mettre ici le code pour afficher une image vide
            --aucun artwork
        end if
    end tell
end try


on make_Image(art_data)
    try
        set open_file to (open for access temp_file with write permission)
        set eof open_file to 0
        write "" to open_file starting at eof -- efface le contenu du fichier, si on utilise toujours le même fichier
        set eof open_file to 512
        write art_data to open_file starting at 513 -- fichier en format pict
        close access open_file
    on error err
        close access temp_file
    end try
    do shell script "/usr/bin/sips -s format jpeg " & quoted form of POSIX path of temp_file -- converti temp_file en fichier JPEG
end make_Image

[MRIC]

Waouh nickel !

Quel est le code pour dire : copie le fichier temp file dans un folder autre ?
J'ai essayé ça :

CODE

duplicate file "private:var:tmp:folders.501:TemporaryItems:artwork_of_current_track.jpg" to folder "Macintosh HD" (replacing yes)

pour essayer, mais ça a pas l'air de vouloir

Le but étant de le mettre dans le fichier pour qu'il apparaisse sur mon site web local
Library:WebServer:Documents:mon_folder_imagetemp

Ce message a été modifié par MRIC - 3 Jul 2007, 09:16.

[Guest_JackJr300_*]

Salut

Quel est le code pour dire : copie le fichier temp file dans un folder autre ?

Le but étant de le mettre dans le fichier pour qu'il apparaisse sur mon site web local
Library:WebServer:Documents:mon_folder_imagetemp

Si le nom du dossier est mon_folder_imagetemp, ceci va fonctionner.

CODE

tell application "Finder" to duplicate file temp_file to folder "Library:WebServer:Documents:mon_folder_imagetemp:" of startup disk with replacing

[Guest_JackJr300_*]

C'est impossible de s'y retrouver dans le dossier Album Artwork : aucun nom clair, une multitude de dossiers et sous-dossiers…

Voici le script qui recherche le fichier ".itc", il fonctionne seulement sur Tiger.

CODE

property temp_file : (path to temporary items as string) & "artwork_of_current_track"
property iTunes_XML : quoted form of POSIX path of ((path to music folder as Unicode text) & "iTunes:iTunes Music Library.xml")
property Artwork_folder : quoted form of POSIX path of ((path to music folder as string) & "iTunes:Album Artwork:")

try
    tell application "iTunes" to set File_Path to location of current track
on error
    return
end try

tell application "Finder" to set these_url_files to URL of document files of (container of File_Path) -- prends tous fichiers de ce dossier "Album ..."
repeat with URl_file in these_url_files
    set persistent_ID to do shell script "/usr/bin/grep -m1 -B6 \"<key>Location</key><string>" & URl_file & "</string>\" " & iTunes_XML & " | /usr/bin/grep  '<key>Persistent ID</key><string>'  | /usr/bin/sed -e 's/^.*<string>//' -e 's~</string>$~~'"
    if persistent_ID is not "" then
        set itc_file to do shell script "/usr/bin/find  " & Artwork_folder & " -mindepth 6 -type f -name *" & persistent_ID & ".itc"
        if itc_file is not "" then
            set t_extension to do shell script "F=" & quoted form of itc_file & "
    isPNG=`grep PNG \"$F\"`
    if [ -n \"$isPNG\" ];then
        EXT=png
    else
        isJPEG=`grep JFIF \"$F\"`
        if [ -n \"$isJPEG\" ];then
            EXT=jpg
        else
            echo 'Format non reconnu'
        exit
        fi
    fi
    tail -c+493 \"$F\" > " & quoted form of POSIX path of temp_file & ".$EXT
    echo $EXT"
            exit repeat
        end if
    end if
end repeat
if itc_file is "" or t_extension contains "Format non reconnu" then return -- aucun artwork pour cet album  ou le format est autre

temp_file & "." & t_extension -- le chemin du nouveau fichier  image (PNG ou JPEG)
POSIX file itc_file -- le chemin du fichier "*****.itc" dans le dossier "/iTunes/Album Artwork:/"

[MRIC]

[quote name='JackJr300' date='3 Jul 2007, 15:39' post='2266824']

CODE

tell application "Finder" to duplicate file temp_file to folder "Library:WebServer:Documents:mon_folder_imagetemp:" of startup disk with replacing

Ca marche pas Ca copie pas ...

HIST des évènement :

tell application "Finder"
copy file "Mini Intel:private:var:tmp:folders.501:TemporaryItems:artwork_of_current_track.jpg" to folder "Mini Intel:Library:WebServer:Documents:itunestemps:"
document file "artwork_of_current_track.jpg"
end tell

Ce message a été modifié par MRIC - 3 Jul 2007, 18:14.

[Guest_JackJr300_*]

Ca marche pas Ca copie pas ...

HIST des évènement :

tell application "Finder"
copy file "Mini Intel:private:var:tmp:folders.501:TemporaryItems:artwork_of_current_track.jpg" to folder "Mini Intel:Library:WebServer:Documents:itunestemps:"
document file "artwork_of_current_track.jpg"
end tell

Je ne comprends pas pourquoi.
Il n'y a pas d'erreur.
Ça a copié quelque part, regarde à la racine du disque de démarrage et dans la maison.


Essaie ceci, s'il n'y a pas d'erreur le fichier dupliqué va etre sélectionné et va etre au premier plan.

CODE

tell application "Finder"
    activate
    set chemin to duplicate alias "Mini Intel:private:var:tmp:folders.501:TemporaryItems:artwork_of_current_track.jpg" to alias "Mini Intel:Library:WebServer:Documents:itunestemps:" with replacing
    reveal chemin
end tell

Ce message a été modifié par JackJr300 - 3 Jul 2007, 19:42.

[MRIC]

je ne trouve pas où ça a copié, ton deuxième script, lui fonctionne bien, et il me révèle le bon endroit ...

[Brys]

Salut,

Désolé pour cette réponse tardive.

JackJr, les 2 scripts que tu m'as proposé correspondent exactement à ce que je cherchais.
Un grand merci !

Je m'en vais les étudier un peu plus en détail (notamment le 2ème).

Ce message a été modifié par Brys - 11 Jul 2007, 10:16.

[Guest_JackJr300_*]

Salut

JackJr, les 2 scripts que tu m'as proposé correspondent exactement à ce que je cherchais.
Un grand merci !

De rien

Si tu as des questions, n'hésite pas.