IPB

Bienvenue invité ( Connexion | Inscription )

4 Pages V  < 1 2 3 4 >  
Reply to this topicStart new topic
> comment supprimer les doublons ds Itunes ?
Options
maclyr
posté 30 Jan 2009, 17:36
Message #31


Nouveau Membre


Groupe : Membres
Messages : 16
Inscrit : 16 Feb 2008
Membre no 107 920



Citation (le jeune bidouilleur @ 22 Jan 2009, 03:33) *
Citation (le jeune bidouilleur @ 13 Jan 2009, 07:49) *

Ca marche pas avec itunes 8.01.
Une solution?
A+ merci

Je relance
Merci

Oui je confirme CE script marche avec iTunes 8 :
Code
script o
    property Les_tracks : missing value
end script

set i to 1
tell application "iTunes"
    set o's Les_tracks to selection
    if o's Les_tracks is {} then return -- aucune selection, quitte le script
    
    set total to (count o's Les_tracks)
    repeat while i < total
        tell item i of o's Les_tracks to set {titre, Lartiste, Lalbum} to {name, artist, album}
        repeat with k from (i + 1) to total --ceci va enlever tous les doublons à la suite ayant le même titre, sauf le premier en surveillant que ca soit le meme album
            tell item k of o's Les_tracks to set {titre2, Lartiste2, Lalbum2, T_ID} to {name, artist, album, database ID}
            if titre2 is titre and Lartiste is Lartiste2 and Lalbum is Lalbum2 then
                tell (get first track of library playlist 1 whose database ID is T_ID)
                    set the_path to location
                    delete -- enleve de la bibliotheque
                    my delete_file(the_path) --mets le fichier dans la corbeille
                end tell
            else
                exit repeat
            end if
        end repeat
        set i to k -- mets la variable (i) à l'index de l'élément dont le titre est différent
    end repeat
end tell

on delete_file(t_file)
    try
        tell application "Finder" to delete t_file -- mets le fichier à la corbeille.
    end try
end delete_file


Ce message a été modifié par maclyr - 30 Jan 2009, 17:37.
Go to the top of the page
 
+Quote Post
le jeune bidouil...
posté 1 Feb 2009, 23:54
Message #32


Macbidouilleur de vermeil !
****

Groupe : Membres
Messages : 1 194
Inscrit : 1 Aug 2005
Lieu : Tahiti
Membre no 43 294



Merci ça marche super!


--------------------
Imac Alu 24" 2.4Ghz 2Go 10.5.4
Dual-core Intel® Atom™- 1 Tb 10.5.6 Serveur
iPhone 8Go 2.1
www.dedimac.com
Go to the top of the page
 
+Quote Post
ldbx
posté 14 Feb 2009, 14:11
Message #33


Nouveau Membre


Groupe : Membres
Messages : 1
Inscrit : 11 May 2007
Membre no 86 358



ca fonctionne sous itunes - mais il y a des faux doublons qui vont etre détecter comme doublons a nettoyer:
ca arrive surtout en classique mais ce n'est pas exclus pour la pop:
dans un meme album deux morceaux differents peuvent porter le meme nom
1 - allegro
2 - adagio
3 - allegro
et le numero de piste n'est pas toujours ajoute au nom du morceau dans l'id3-Tag ...
donc soit il faut de plus tester l'egalité des numeros de piste -
une logique serait :
-2 numeros de piste differents : c'est pas un doublon
-2 numeros identiques : c'est un doublon
-1 seul numero: a priori c'est un doublon
- aucun numero: a priori c'est un doublon
Go to the top of the page
 
+Quote Post
Guest_EricaL**_*
posté 14 Feb 2009, 21:36
Message #34





Guests






Bonjour,

Citation (ldbx @ 14 Feb 2009, 08:11) *
ca fonctionne sous itunes - mais il y a des faux doublons qui vont etre détecter comme doublons a nettoyer:
ca arrive surtout en classique mais ce n'est pas exclus pour la pop:

donc soit il faut de plus tester l'egalité des numeros de piste -
une logique serait :
-2 numeros de piste differents : c'est pas un doublon
-2 numeros identiques : c'est un doublon
-1 seul numero: a priori c'est un doublon
- aucun numero: a priori c'est un doublon

Ce n'est pas vraiment compliqué à modifier.
Voici le script :
Code
script o
    property Les_tracks : missing value
end script

set i to 1
tell application "iTunes"
    set o's Les_tracks to selection
    if o's Les_tracks is {} then return -- aucune sélection, quitte le script
    
    set total to (count o's Les_tracks)
    repeat while i < total
        tell item i of o's Les_tracks to set {titre, Lartiste, Lalbum, T_ID, No_piste} to {name, artist, album, database ID, track number}
        repeat with k from (i + 1) to total --ceci va enlever tous les doublons à la suite ayant le même titre,  même album, no de piste
            tell item k of o's Les_tracks to set {titre2, Lartiste2, Lalbum2, T_ID2, No_piste2} to {name, artist, album, database ID, track number}
            if titre2 is titre and Lartiste is Lartiste2 and Lalbum is Lalbum2 then
                if T_ID is not T_ID2 then if No_piste = No_piste2 or No_piste = 0 or No_piste2 = 0 then tell (get first track of library playlist 1 whose database ID is T_ID2)
                    set the_path to location
                    delete --supprime de la bibliothèque
                    my delete_file(the_path) --mets le fichier dans la corbeille
                end tell
            else
                exit repeat
            end if
        end repeat
        set i to k -- mets la variable (i) à l'index de l'élément dont le titre est différent
    end repeat
end tell

on delete_file(t_file)
    try
        tell application "Finder" to delete t_file
    end try
end delete_file

Si le numéro de la piste n'est pas défini dans le tag, iTunes donnera 0 pour le numéro de piste dans un AppleScript.
Donc si un des deux numéros de pistes est 0 ou les deux numéros s'équivalent, le script va le supprimer.

J'ai ajouté la vérification de la "database ID" en cas de doublon dans une liste de lecture personnalisée, car on peut ajouté des doublons qui auront le même fichier comme référence, sinon le fichier unique sera effacé.
Mais, ce n'est pas possible d'avoir la même "database ID" sur les pistes dans une de ces bibliothèques ( Musique, Films, etc..)
Go to the top of the page
 
+Quote Post
mala116
posté 26 Feb 2009, 14:45
Message #35


Nouveau Membre


Groupe : Membres
Messages : 9
Inscrit : 20 Nov 2007
Lieu : LAM60 - Oise
Membre no 100 410



Merci beaucoup, le script marche impeccable sur la dernière version itunes


--------------------
iMac alu 24" 2.8gg 8800gs
Macbook blanc 2gg
iTouch 1G 8gg
Go to the top of the page
 
+Quote Post
Tomeno
posté 31 Mar 2009, 17:31
Message #36


Macbidouilleur d'Or !
*****

Groupe : Modérateurs
Messages : 3 052
Inscrit : 18 May 2002
Lieu : Base de la tranquilité/Planéte Lune/Cratére n°3.
Membre no 2 501



Citation (EricaL** @ 14 Feb 2009, 22:36) *
Ce n'est pas vraiment compliqué à modifier.


Une modif supplémentaire sympa serait
  1. d'avoir un écran d'accueil expliquant que le script va enlever tous les doublons ayant le même titre, même album, no de piste
  2. ajouter une instruction selectionnant tous les morceaux de la liste (Commande A) avant de poursuivre le script


Ce message a été modifié par Tomeno - 31 Mar 2009, 17:32.


--------------------
Hackeur vaillant ... rien d'impossible !
Mac Pro "corbeille" 2013 3,7 Ghz, SSD 500 Go, + Ecran Nec 30"/ iMac Retina 2014, 4 GHz, écran 27 " / Mac Pro "camion" 2008 / Imac G4 Tournesol 1,25 GHz 20" , modifié Mac Mini M1/ Cube G4 boosté à 1,8Ghz avec carte Gigadesign +Geforce 6200+AppleDisplay 23" / Spartacus upgradé G3 / MacBook polycarbonate 2011 / MacBook pro 17 pouces / Freebox Révolution V6 / Wifi Mesh avec 4 boitiers Tenda Nova MW6
Go to the top of the page
 
+Quote Post
Guest_EricaL**_*
posté 1 Apr 2009, 00:37
Message #37





Guests






Bonjour,

Citation (Tomeno @ 31 Mar 2009, 12:31) *
Citation (EricaL** @ 14 Feb 2009, 22:36) *
Ce n'est pas vraiment compliqué à modifier.


Une modif supplémentaire sympa serait
  1. d'avoir un écran d'accueil expliquant que le script va enlever tous les doublons ayant le même titre, même album, no de piste
  2. ajouter une instruction selectionnant tous les morceaux de la liste (Commande A) avant de poursuivre le script


Voici le script modifié.
Code
script o
    property Les_tracks : missing value
end script
set reussi to 0
set non_reussi to 0

display dialog "                             Attention !" & return & return & "Ce script va supprimer tous les doublons" & return & "ayant le même titre, le même album" & return ¬
    & "et le même numéro de piste" & return & "à partir des pistes sélectionnées" with title "Supprimer des  doublons" buttons {"Quitter le script", "Continuer"} cancel button "Quitter le script"

set i to 1
tell application "iTunes"
    set o's Les_tracks to selection
    if o's Les_tracks is {} then error "Vous devez sélectionner des pistes avant d'exécuter ce script."
    
    set total to (count o's Les_tracks)
    repeat while i < total
        tell item i of o's Les_tracks to set {titre, Lartiste, Lalbum, T_ID, No_piste} to {name, artist, album, database ID, track number}
        repeat with k from (i + 1) to total --ceci va enlever tous les doublons à la suite ayant le même titre,  même album, no de piste
            tell item k of o's Les_tracks to set {titre2, Lartiste2, Lalbum2, T_ID2, No_piste2} to {name, artist, album, database ID, track number}
            if titre2 is titre and Lartiste is Lartiste2 and Lalbum is Lalbum2 then
                if T_ID is not T_ID2 then
                    if No_piste = No_piste2 or No_piste = 0 or No_piste2 = 0 then
                        tell (get first track of library playlist 1 whose database ID is T_ID2)
                            set the_path to location
                            if my delete_file(the_path) then
                                delete --supprime de la bibliothèque
                                set reussi to reussi + 1
                            else
                                set non_reussi to non_reussi + 1
                            end if
                        end tell
                    end if
                else --même database id : supprime de la liste de lecture seulement , pas dans la  bibliotheque, ni sur le disque
                    delete item k of o's Les_tracks
                end if
            else
                exit repeat
            end if
        end repeat
        set i to k -- mets la variable (i) à l'index de l'élément dont le titre est différent
    end repeat
end tell
display dialog "" & reussi & " doublons supprimés." & return & non_reussi & " doublons non supprimés"

on delete_file(t_file)
    try
        tell application "Finder" to delete t_file
        return true
    end try
    return false
end delete_file


Ce message a été modifié par EricaL** - 3 Apr 2009, 19:19.
Go to the top of the page
 
+Quote Post
Tomeno
posté 1 Apr 2009, 17:39
Message #38


Macbidouilleur d'Or !
*****

Groupe : Modérateurs
Messages : 3 052
Inscrit : 18 May 2002
Lieu : Base de la tranquilité/Planéte Lune/Cratére n°3.
Membre no 2 501



Citation (EricaL** @ 1 Apr 2009, 01:37) *
Voici le script modifié.


merci+++
manque plus qu'un petit display dialog final pour annoncer que tout s'est bien passé (et afficher le nombre de fichiers supprimés ??? )

Mais ce qui est curieux dans ton script c'est qu'au moment ou il faut faire le Commande A, la fenêtre d'iTunes est "hidden"

Ce message a été modifié par Tomeno - 2 Apr 2009, 11:19.


--------------------
Hackeur vaillant ... rien d'impossible !
Mac Pro "corbeille" 2013 3,7 Ghz, SSD 500 Go, + Ecran Nec 30"/ iMac Retina 2014, 4 GHz, écran 27 " / Mac Pro "camion" 2008 / Imac G4 Tournesol 1,25 GHz 20" , modifié Mac Mini M1/ Cube G4 boosté à 1,8Ghz avec carte Gigadesign +Geforce 6200+AppleDisplay 23" / Spartacus upgradé G3 / MacBook polycarbonate 2011 / MacBook pro 17 pouces / Freebox Révolution V6 / Wifi Mesh avec 4 boitiers Tenda Nova MW6
Go to the top of the page
 
+Quote Post
Keam
posté 2 Apr 2009, 13:53
Message #39


Nouveau Membre


Groupe : Membres
Messages : 5
Inscrit : 4 Mar 2009
Membre no 132 258



Salut,
Qu'elle est la cible de ce script? La bibliothèque? Peut-on spécifier une liste de lecture en paramètre d'entrée?

Merci.
Go to the top of the page
 
+Quote Post
Guest_EricaL**_*
posté 2 Apr 2009, 21:29
Message #40





Guests






Citation (Tomeno @ 1 Apr 2009, 12:39) *
manque plus qu'un petit display dialog final pour annoncer que tout s'est bien passé (et afficher le nombre de fichiers supprimés ??? )

J'ai modifié le script dans le message #37

Ajout dans le script : supprime une piste dans une liste de lecture personnelle ayant la même référence (database id) .
Cela ne supprime rien dans la bibliothèque, ni sur le disque.

Citation (Tomeno @ 1 Apr 2009, 12:39) *
Mais ce qui est curieux dans ton script c'est qu'au moment ou il faut faire le Commande A, la fenêtre d'iTunes est "hidden"

La fenêtre est invisible ? blink.gif

Ici, la fenêtre est juste en arrière du dialogue. smile.gif

Ce message a été modifié par EricaL** - 2 Apr 2009, 21:35.
Go to the top of the page
 
+Quote Post
Guest_EricaL**_*
posté 2 Apr 2009, 22:08
Message #41





Guests






Bonsoir,

Citation (Keam @ 2 Apr 2009, 08:53) *
Salut,
Qu'elle est la cible de ce script? La bibliothèque?

La cible est sur les pistes sélectionnées.
Oui, c'est sur la bibliothèque en général qu'on utilise ce script , mais ça fonctionne aussi sur les listes de lecture.


Citation (Keam @ 2 Apr 2009, 08:53) *
Peut-on spécifier une liste de lecture en paramètre d'entrée?

Merci.

Oui, mais la liste de lecture doit être triée par nom pour que le script fonctionne.
Code
script o
    property Les_tracks : missing value
end script

set i to 1
tell application "iTunes"
    set o's Les_tracks to tracks of user playlist "liste sans titre" -- ***  titre de votre liste de lecture ****
    if o's Les_tracks is {} then return -- aucune pistes dans la listes de lecture
    
    set total to (count o's Les_tracks)
    repeat while i < total
        tell item i of o's Les_tracks to set {titre, Lartiste, Lalbum, T_ID, No_piste} to {name, artist, album, database ID, track number}
        repeat with k from (i + 1) to total --ceci va enlever tous les doublons à la suite ayant le même titre,  même album, no de piste
            tell item k of o's Les_tracks to set {titre2, Lartiste2, Lalbum2, T_ID2, No_piste2} to {name, artist, album, database ID, track number}
            if titre2 is titre and Lartiste is Lartiste2 and Lalbum is Lalbum2 then
                if T_ID is not T_ID2 then
                    if No_piste = No_piste2 or No_piste = 0 or No_piste2 = 0 then
                        tell (get first track of library playlist 1 whose database ID is T_ID2)
                            set the_path to location
                            if my delete_file(the_path) then delete --supprime de la bibliothèque et de la liste de lecture
                        end tell
                    end if
                else --même database id : supprime de la liste de lecture seulement , pas dans la  bibliotheque, ni sur le disque
                    delete item k of o's Les_tracks
                end if
            else
                exit repeat
            end if
        end repeat
        set i to k -- mets la variable (i) à l'index de l'élément dont le titre est différent
    end repeat
end tell


on delete_file(t_file)
    try
        tell application "Finder" to delete t_file
        return true
    end try
    return false
end delete_file

Go to the top of the page
 
+Quote Post
Keam
posté 3 Apr 2009, 10:14
Message #42


Nouveau Membre


Groupe : Membres
Messages : 5
Inscrit : 4 Mar 2009
Membre no 132 258



Ok merci je vais essayer çà.

En fait pour l'instant je me sers d'Automator pour ajouter dans ma liste "new" tous les mp3 de mon dossier "A_ajouter". Et comme Automator n'a pas de fonction qui vérifie que ce qu'il ajoute n'est pas déjà présent dans la liste çà me fait plein de doublons. C'est là que je fais entrer le script en jeu: lui passer la liste "new" en paramètre d'entrée et qu'il en supprime les doublons.

EDIT: J'execute le script par l'intermédiaire d'automator et il ne me supprime rien. Biensur je sélectionne au préalable mes doublons dans iTunes et ensuite j'execute le script, aucun problème détecté à l'execution mais aucun doublon supprimé.

Je prends le script du message #37 et pour l'executer je dois enlever la message box:

display dialog " Attention !" & return & return & "Ce script va supprimer tous les doublons" & return & "ayant le même titre, le même album" & return
& "et le même numéro de piste" & return & "à partir des pistes sélectionnées" with title "Supprimer des doublons" buttons {"Quitter le script", "Continuer"} cancel button "Quitter le script"

Sinon il me dit qu'il y a une erreur dans le script.

Ce message a été modifié par Keam - 3 Apr 2009, 10:34.
Go to the top of the page
 
+Quote Post
Tomeno
posté 3 Apr 2009, 18:20
Message #43


Macbidouilleur d'Or !
*****

Groupe : Modérateurs
Messages : 3 052
Inscrit : 18 May 2002
Lieu : Base de la tranquilité/Planéte Lune/Cratére n°3.
Membre no 2 501



Citation (EricaL** @ 2 Apr 2009, 22:29) *
J'ai modifié le script dans le message #37

Ajout dans le script : supprime une piste dans une liste de lecture personnelle ayant la même référence (database id) .
Cela ne supprime rien dans la bibliothèque, ni sur le disque.

La fenêtre est invisible ? blink.gif
Ici, la fenêtre est juste en arrière du dialogue. smile.gif

Merci++ MAIS :
Chez moi la fenétre d'iTunes continue d'être invisible (et pourtant elle est plus grande que celle du dialogue donc si elle était derriere je devrais la voir): je dois cliquer sur l'icone d'iTunes dans le dock pour la rendre visible
De plus la version qui est dans le message 37 ne supprime plus rien du tout
Et en fait ce qui serait bien c'est un script qui supprime vraiement les doublons de la bibliothéque, du moins c'est ça que je cherchais


--------------------
Hackeur vaillant ... rien d'impossible !
Mac Pro "corbeille" 2013 3,7 Ghz, SSD 500 Go, + Ecran Nec 30"/ iMac Retina 2014, 4 GHz, écran 27 " / Mac Pro "camion" 2008 / Imac G4 Tournesol 1,25 GHz 20" , modifié Mac Mini M1/ Cube G4 boosté à 1,8Ghz avec carte Gigadesign +Geforce 6200+AppleDisplay 23" / Spartacus upgradé G3 / MacBook polycarbonate 2011 / MacBook pro 17 pouces / Freebox Révolution V6 / Wifi Mesh avec 4 boitiers Tenda Nova MW6
Go to the top of the page
 
+Quote Post
Guest_EricaL**_*
posté 3 Apr 2009, 19:52
Message #44





Guests






Bonjour,

Citation (Tomeno @ 3 Apr 2009, 13:20) *
Chez moi la fenétre d'iTunes continue d'être invisible (et pourtant elle est plus grande que celle du dialogue donc si elle était derriere je devrais la voir): je dois cliquer sur l'icone d'iTunes dans le dock pour la rendre visible

Il n'y a rien dans le script qui met la fenêtre dans le Dock.

Sil ce n'est pas un bogue, la seule raison qui expliquerait la fenêtre invisible, c'est qu’iTunes n'est pas visible ou lancée quand tu exécutes le script.
Dans ce cas, il suffit de mettre activate après la ligne : (tell application "iTunes")
Code
tell application "iTunes"
activate

Sinon, donne-nous plus de détails.

Citation (Tomeno @ 3 Apr 2009, 13:20) *
De plus la version qui est dans le message 37 ne supprime plus rien du tout

J'avais oublié d'enlever un return et de compter les fichiers supprimés, c'est corrigé maintenant.

Citation (Tomeno @ 3 Apr 2009, 13:20) *
Et en fait ce qui serait bien c'est un script qui supprime vraiement les doublons de la bibliothéque, du moins c'est ça que je cherchais

Ce script fait cela.
Ce que j'ai fait, c'est d'ajouter (selon les demandes) des dialogues, compter les pistes supprimées et d'ajouter certaines conditions comme le numéro de piste avant de supprimer, le but du script est toujours le même, c'est de supprimer les doublons.

J'ai fait des tests et le script fonctionne bien ici.
Si, avec ces ajouts le script ne fonctionne pas pour vous, vous pouvez utiliser le script du message #31 ou le script original du message #5.

Ce message a été modifié par EricaL** - 3 Apr 2009, 19:54.
Go to the top of the page
 
+Quote Post
Tomeno
posté 4 Apr 2009, 17:11
Message #45


Macbidouilleur d'Or !
*****

Groupe : Modérateurs
Messages : 3 052
Inscrit : 18 May 2002
Lieu : Base de la tranquilité/Planéte Lune/Cratére n°3.
Membre no 2 501



Citation (EricaL** @ 3 Apr 2009, 20:52) *
Citation (Tomeno @ 3 Apr 2009, 13:20) *
De plus la version qui est dans le message 37 ne supprime plus rien du tout

J'avais oublié d'enlever un return et de compter les fichiers supprimés, c'est corrigé maintenant.


Oui ça remarche bien ainsi

Quand je te disais qu' en lançant le script ça faisait disparaitre la fenetre d'Itunes et que je devais cliquer dans le dock pour la rendre visible, ce n'est pas que la fenetre d'iTunes se mettais dans le dock, c'est qu'elle disparait comme quand on fait "masquer l'application" (Option, Commabde, H) et c'est sur l'icone de l'application, pas sur sa fenetre rangée dans le dock, que je dois cliquer. Mais bon c'est un inconvénient mineur.

Ce message a été modifié par Tomeno - 4 Apr 2009, 17:15.


--------------------
Hackeur vaillant ... rien d'impossible !
Mac Pro "corbeille" 2013 3,7 Ghz, SSD 500 Go, + Ecran Nec 30"/ iMac Retina 2014, 4 GHz, écran 27 " / Mac Pro "camion" 2008 / Imac G4 Tournesol 1,25 GHz 20" , modifié Mac Mini M1/ Cube G4 boosté à 1,8Ghz avec carte Gigadesign +Geforce 6200+AppleDisplay 23" / Spartacus upgradé G3 / MacBook polycarbonate 2011 / MacBook pro 17 pouces / Freebox Révolution V6 / Wifi Mesh avec 4 boitiers Tenda Nova MW6
Go to the top of the page
 
+Quote Post
lalywizz
posté 24 May 2009, 18:36
Message #46


Nouveau Membre


Groupe : Membres
Messages : 1
Inscrit : 24 May 2009
Membre no 136 566



Toutes ces informations sont ultra pratiques pour un ménage bien fait!!!!


Toutefois, il resterait un petit détail afin que ce script soit complet à 100%.

Prenons par exemple deux fichiers mp3 qui soient identiques, mais que l'un des deux aie un tag plus complet que l'autre (ex. avec l'info: artiste de l'album, année, genre, etc) et pas l'autre.
Comment savoir, en supprimant nos doublons, que nous effaçons réellement le fichiers que l'on veut (dans ce cas-ci, moi j'aurais gardé le fichier avec l'info complète et pas seulement celui avec l'info titre et artiste seulement)?

Serait-ce possible d'ajouter à ce script une mention quant à la date de l'ajout de ce fichier (dans la bibliothèque iTunes), afin de pouvoir préciser que l'on voudrait supprimer le fichier le plus ancien ou le plus récent (ou selon une date précise)?
Ou encore, en ajoutant à ce script une autre précision du genre (ex. supprimer que les fichiers dont la section "artiste de l'album" est vide).

Je pose cette question à savoir si ceux qui ont les notions pour corriger ce script peuvent ajouter cet élément de précision. Car avec la dernière version de ce script (dans ce forum), mon ménage s'est très bien exécuté, mais certains fichiers avec les infos "incomplètes" ont eu préséances sur les fichiers avec les infos complètes, et ça demande maintenant des manipulations supplémentaires pour rectifier la chose.


Merci!

Ce message a été modifié par lalywizz - 25 May 2009, 03:28.
Go to the top of the page
 
+Quote Post
Guest_EricaL**_*
posté 27 May 2009, 07:45
Message #47





Guests






Bonjour,

Citation (lalywizz @ 24 May 2009, 13:36) *
Serait-ce possible d'ajouter à ce script une mention quant à la date de l'ajout de ce fichier (dans la bibliothèque iTunes), afin de pouvoir préciser que l'on voudrait supprimer le fichier le plus ancien ou le plus récent ?

Pour ça, il suffit de trier la colonne "Date de l'ajout" en ascendant et de cliquer sur la colonne "Nom" si tu veux supprimer les doublons les plus récents.

Ou de trier la colonne "Date de l'ajout" en descendant et de cliquer sur la colonne "Nom" pour supprimer les doublons les plus anciens.

Go to the top of the page
 
+Quote Post
cisfr
posté 28 May 2009, 20:51
Message #48


Macbidouilleur de bronze !
**

Groupe : Membres
Messages : 296
Inscrit : 16 Nov 2002
Membre no 4 703



merci ,merci 12 gigas récupérés en ce qui me concerne ...Faut dire que c'était un sacré souk dans mes MP3....
Go to the top of the page
 
+Quote Post
agyeman
posté 19 Jul 2009, 10:34
Message #49


Nouveau Membre


Groupe : Membres
Messages : 1
Inscrit : 19 Jul 2009
Membre no 139 377



Une petie astuce consiste à rechercher les doubles exactes dans i Tunes en appuyant sur la touche option (alt) en cliquant sur la recherche des doubles dans fichier.
Go to the top of the page
 
+Quote Post
vivendora
posté 23 Jul 2009, 00:24
Message #50


Nouveau Membre


Groupe : Membres
Messages : 1
Inscrit : 23 Jul 2009
Membre no 139 565



tout d'abord un GRAND GRAND MERCIIIIIII a tous pour vos conseils, ca fait des mois que je me prends la tete a essayer de tout effacer manuellement ; et généralement ca me déprime au bout de 10 min ( voire 5!) , bref 1274 doublons effacés , presque 9 Go ..... Le scripte est génial !
Merci encore c'est vraiment sympa de prendre du temps pour partager les astuces . Encore merci et bravo biggrin.gif
Go to the top of the page
 
+Quote Post
liomega
posté 24 Jul 2009, 10:23
Message #51


Nouveau Membre


Groupe : Membres
Messages : 11
Inscrit : 10 Feb 2008
Membre no 107 422



petite question stupide oups...
comment on exécute un script?
ou doit le mettre?
je suis novice avec mon macbookpro...
merci de votre aide
Go to the top of the page
 
+Quote Post
ades
posté 24 Jul 2009, 10:53
Message #52


Macbidouilleur d'Or !
*****

Groupe : Membres
Messages : 2 818
Inscrit : 23 Nov 2002
Membre no 4 808



c'est expliqué plus haut rolleyes.gif


--------------------
MBP 15 unibody 2,4 Ghz , 4Go ssd 256 Go, dual boot OSX10.9.5-Linux mint
MacMini late 2012, i7 2,3Ghz, 16Go, 2 ssd 1to, OSX Sonoma 14.4 (OpencoreLegacy 1.2.1 1.3.0 1.4.0 1.4.1 1.4.2)
Go to the top of the page
 
+Quote Post
Byrdland
posté 14 Sep 2009, 16:39
Message #53


Nouveau Membre


Groupe : Membres
Messages : 7
Inscrit : 27 Feb 2006
Membre no 56 485



Tous mes remerciements à Jack jr 300 pour son script magique !!
J'étais face à 18 000 doublons ...... voilà tout est réglé.
ll y a longtemps j'ai fait de la programmation, applescript me donne envie de m'y remettre !

NB Une petite chose que je ne m'explique pas :
Un ami m'avait transmis par mail le fameux script...... cela ne fonctionnait pas, en allant sur le forum et en recopiant le texte du script à partir du message original, l'éditeur de script a reconnu les instructions qui sont apparues en bleu, et le script a démarré !
smile.gif smile.gif smile.gif smile.gif
Go to the top of the page
 
+Quote Post
LeVifArgent!
posté 27 Sep 2009, 16:56
Message #54


Adepte de Macbidouille
*

Groupe : Membres
Messages : 122
Inscrit : 22 Oct 2006
Lieu : Mercury
Membre no 71 102



Le script du message #37 fonctionne impecc' !
Merci vraiment smile.gif


--------------------
MacBookPro 2009 Unibody 15,4 pouces Intel Core 2 Duo 2,6 GHz 8 Go de mémoire SDRAM DDR3 1.066 MHz SSD 400 Go
Mac mini 2009 2 GHz 4 Go de mémoire SDRAM DDR3 1.066 MHz SSD 120 Go
iPhone 4GS 32Go
Go to the top of the page
 
+Quote Post
babyboy177
posté 14 Nov 2009, 15:30
Message #55


Nouveau Membre


Groupe : Membres
Messages : 2
Inscrit : 3 Sep 2008
Membre no 120 874



Je relance pour Itunes 9.0.2 .
Lorsque je veux lancer le script, il me dit qu'il n'y pas de doublons, or j'en ai pas mal. =D

Si quelqu'un avait la solution.
Go to the top of the page
 
+Quote Post
Guest_EricaL**_*
posté 15 Nov 2009, 01:44
Message #56





Guests






Bonjour,

Citation (babyboy177 @ 14 Nov 2009, 09:30) *
Je relance pour Itunes 9.0.2 .
Lorsque je veux lancer le script, il me dit qu'il n'y pas de doublons, or j'en ai pas mal. =D

Le script du message #37 fonctionne ici sur Itunes 9.0.2
Go to the top of the page
 
+Quote Post
joon59
posté 21 Nov 2009, 20:02
Message #57


Nouveau Membre


Groupe : Membres
Messages : 3
Inscrit : 21 Nov 2009
Membre no 145 834



Impec, ça marche parfaitement, le mac fait le boulot a ma place, en espérant qu'il fait pas trop le ménage non plus lol.
Go to the top of the page
 
+Quote Post
serpiko69
posté 22 Nov 2009, 16:37
Message #58


Nouveau Membre


Groupe : Membres
Messages : 18
Inscrit : 8 Nov 2008
Membre no 125 221



Ca fonctionne je suis bluffé...
merci !
Go to the top of the page
 
+Quote Post
Natacha Pitre
posté 22 Nov 2009, 18:33
Message #59


Nouveau Membre


Groupe : Membres
Messages : 2
Inscrit : 22 Nov 2009
Lieu : Montpellier
Membre no 145 885



merci pour ce script, je viens de faire le ménage en deux temps trois mouvements
Go to the top of the page
 
+Quote Post
Gohu
posté 4 Dec 2009, 19:42
Message #60


Adepte de Macbidouille
*

Groupe : Membres
Messages : 54
Inscrit : 23 Jan 2009
Membre no 129 944



Bonjour tout le monde,

désolé de te relancer Erical**, mais personnellement j'aimerais supprimer les doublons seulement s'ils ont exactement le même nom, le même album, le même artiste, pourquoi pas le même numéro de piste (pour l'instant rien de nouveau), mais surtout la même taille et la même durée.

J'imagine qu'il suffit pour ça que je rajoute Size et Time après No_piste ou track number dans le script, seulement je ne sais pas exactement quel nom donner (je ne sais absolument pas créer un script). Je veux dire que par exemple pour vérifier que les doublons aient bien le même numéro de piste tu marques No_piste dans la première parenthèse, et track number dans la deuxième, donc je ne sait pas trop quoi mettre. Si ça ne t'embête pas trop, tu pourrais me dire quoi faire exactement ?

Je te remercie !


--------------------
Mac OS X 10,6,2
Processeur intel core 2 duo, 2 GHz
Go to the top of the page
 
+Quote Post

4 Pages V  < 1 2 3 4 >
Reply to this topicStart new topic
1 utilisateur(s) sur ce sujet (1 invité(s) et 0 utilisateur(s) anonyme(s))
0 membre(s) :

 



Nous sommes le : 29th March 2024 - 02:34