comment supprimer les doublons ds Itunes ?

[Jutamarin]

Salutations

Merci pour vos précieuses infos.

Petite demande/suggestion pour ce super script :
Si c'est possible faire en sorte qu'il puisse préserver le doublon dont la qualité est la meilleure, c'est à dire concrètement qu'il garde celui en 192 Kbit/s et dégage le 64 Kbit/s.

[Guest_EricaL**_*]

Bonjour,

Petite demande/suggestion pour ce super script :
Si c'est possible faire en sorte qu'il puisse préserver le doublon dont la qualité est la meilleure,

Voici le script qui supprime les doublons, mais garde le morceau ayant le plus grand débit (kbit/s)

Code

script o
    property Les_tracks : missing value
end script
display dialog "Attention !" & return & return & "Ce script va supprimer tous les doublons" & return & "ayant le même (titre, album et numéro de piste)" & return & "à partir des pistes sélectionnées, la piste ayant le plus haut débit sera conservé" with title "Supprimer des  doublons" buttons {"Quitter le script", "Continuer"} cancel button "Quitter le script"

set {reussi, non_reussi, i} to {0, 0, 1}
tell application "iTunes"
    set o's Les_tracks to selection
    set total to (count o's Les_tracks)
    if total < 2 then error "Vous devez sélectionner deux pistes  ou plus avant d'exécuter ce script."
    
    repeat while i < total
        tell (get item i of o's Les_tracks) to set {titre, Lartiste, Lalbum, T_ID, Le_debit} to {name, artist, album, database ID, bit rate}
        
        repeat with k from (i + 1) to total --ceci va enlever tous les doublons à la suite ayant le même titre,  même album, no de piste
            tell (get item k of o's Les_tracks) to if name = titre and artist = Lartiste and album = Lalbum then
                set {T_ID2, Le_debit2} to {database ID, bit rate}
            else
                exit repeat
            end if
            if T_ID is not T_ID2 then
                if Le_debit2 > Le_debit then -- vérifie le débit, garde le plus grand débit
                    set the_ID to T_ID
                    set {T_ID, Le_debit} to {T_ID2, Le_debit2}
                    set T_ID2 to the_ID
                end if
                tell (get first track of library playlist 1 whose database ID is T_ID2)
                    if my delete_file(get location) then
                        delete --supprime de la bibliothèque
                        set reussi to reussi + 1
                    else
                        set non_reussi to non_reussi + 1
                    end if
                end tell
            else --même database id : supprime de la liste de lecture seulement , pas dans la  bibliotheque, ni sur le disque
                delete item k of o's Les_tracks
            end if
        end repeat
        set i to k -- mets la variable (i) à l'index de l'élément dont le titre est différent
    end repeat
end tell
set o's Les_tracks to {}
activate
display dialog "" & reussi & " doublons supprimés." & return & non_reussi & " doublons non supprimés"

on delete_file(t_file)
    try
        tell application "Finder" to delete t_file
        return true
    end try
    return false
end delete_file

[Guest_EricaL**_*]

erreur

Ce message a été modifié par EricaL** - 26 Aug 2011, 03:27.

[Guest_EricaL**_*]

erreur

Ce message a été modifié par EricaL** - 26 Aug 2011, 03:27.

[ThomasD-74]

Salut a tous !

J'ai un nouveau petit truc a vous demandez... je voudrait effacer mes doublons mais sur mon I-POD et j'ai bien essayer le scripts mais rien y fait... Merci d'avance ; )

[ccciolll]

AU passage, j'indique tout de mêm que dans iTunes 9 (le 9.2.1 chez moi, exactement) le classement par doublon se cache dans le menu "fichiers"

Par contre il est plutôt mal fait, il cherche les doublons via le titre du morceau. Ce qui est d'une part inexact car on peut avoir plusieurs versions du même titre, et ce qui est également incomplet car on peut aussi avoir le même fichier avec un titre différent (ce qui n'est pas rare avec les titres importés de CDDB, notamment dans le classique ou les compiles).

Une sélection intelligente devrait pouvoir se faire sur le poids du fichier à l'octet près, en ignorant les autres indices.
Ou encore sur la durée à la micro-seconde près, pour le cas où l'on aurait un titre encodé un coup en 8 kbps et l'autre coup en 128 kbps, qui seraient donc identiques à la source mais sans faire le même poids.

Ce message a été modifié par ccciolll - 5 Dec 2011, 10:21.

[yannick.cattin]

Bonjour,

Le script ci-dessus marche nickel. Encore un grand merci à l'auteur.

Je me demandais si il serait également possible de supprimer les titres qui comportent des points d'interrogations à l'aide d'un script.

Si quelqu'un peut me renseigner se serait super sympa.

Salutations.

[Jack the best]

Il y a certains titres qui en contiennent vraiment !

Tu peux toujours faire une recherche dans iTunes et mettant un point d'interrogation et en sélectionnant non pas tous, mais Morceau !

Je viens de chercher et j'en ai plein de titres avec des ? légitimes, puisque le titre est une question !

Si tu n'en veux pas, tu les sélectionnes ensuite et tu les vires…

[ccciolll]

Ah tiens, ça m'a fait découvrir qu'il y avait un menu déroulant sous la loupe de recherche…

[Jack the best]

On en apprend tous les jours !

[Rinocerrone]

On en apprend tous les jours !

Bien dit papi

[yannick.cattin]

Bonsoir,

Je voulais dire y a-t-il possibilité d'effacer avec un script les titres qui sont indexés par iTunes avec un point d'exclamation (qui signifie que les morceaux sont introuvables) ?

[Manu75010]

Si l'on accepte de perdre les listes de lecture, le plus simple est de vider toute la biliothèque puis de tout réimporter. C'est radical !

[MlleCat]

Bonjour à tous, j'ai la toute dernière version de itune 10.5.3.3 et je ne trouve même pas où on lance le script, merci de votre aide...

[yangon]

Bonsoir,

Il faut le copier et coller dans l'application "Éditeur de script", il est dans le dossier "AppleScript" du dossier "Applications"

Bonjour,
en tant que néophyte j'ai eu du mal à trouver cet Editeur de Script. en fait sous Mountain Lion il se trouve dans le dossier "Utilitaires" de "Applications".