NUMBERS : Comment faire une addition de cellules situées dans plusieurs feuilles

[Lohuli]

Bonjour lézamis,

je me suis fait un bon de commande sous Numbers.
Pour pouvoir interagir j'ai tout fait dans un seul document avec autant de feuilles de que de commandes.
Je voudrais pouvoir dans une dernière feuille faire les additions de tous les articles.
Je n'ai pas trouvé de formule pour ça.
Pour le moment, j'ai fait une formule à la main pour le premier article que j'ai ensuite glissé pour tous les autres articles.
Ça fonctionne mais l'inconvénient est quand une commande se rajoute je dois tout recommencer.
Je me doute qu'il y a une formule pour additionner automatiquement toutes les cellules sur une plage donnée de feuilles mais je ne l'ai pas trouvée.
Je vous joins la formule telle qu'elle est actuellement.

29::invoice::A12+28::invoice::A12+27::invoice::A12+26::invoice::A12+25::invoice:
:A12+24::invoice::A12+23::invoice::A12+22::invoice::A12+21::invoice::A12+20::invo
ice::A12+19::invoice::A12+18::invoice::A12+17::invoice::A12+16::invoice::A12+15::
invoice::A12+14::invoice::A12+13::invoice::A12+12::invoice::A12+11::invoice::A12+
10::invoice::A12+9::invoice::A12+8::invoice::A12+7::invoice::A12+6::invoice::A12+
5::invoice::A12+4::invoice::A12+3::invoice::A12+2::invoice::A12+1::invoice::A12

Merci de votre aide.

[apoca]

Salut,

Pour ta formule, tu ne tapes que les +…
Toutes les adresses de cellules sont mises automatiquement en navigant de feuille en feuille et en cliquant sur les cellules dont on veut faire la somme…

Ce message a été modifié par apoca - 13 May 2015, 22:12.

[baron]

Oui, mais dans la mesure où c'est toujours la même cellule sur des feuilles différentes, ça serait plus simple s'il y avait moyen de spécifier qu'on veut la somme de toutes les cellules A12 à travers une plage de feuilles… 

[Lohuli]

Salut,

Pour ta formule, tu ne tapes que les +…
Toutes les adresses de cellules sont mises automatiquement en navigant de feuille en feuille et en cliquant sur les cellules dont on veut faire la somme…

Ça, c'est ce que j'ai fait, cliquer sur chaque cellule dans chaque feuille mais ça prend un temps fou et surtout, à chaque nouvelle commande, il faut recommencer.

Oui, mais dans la mesure où c'est toujours la même cellule sur des feuilles différentes, ça serait plus simple s'il y avait moyen de spécifier qu'on veut la somme de toutes les cellules A12 à travers une plage de feuilles… 

Voilà, c'est exactement le but de mon post, il doit forcément y avoir une formule qui permet ça mais je ne l'ai trouvée nulle part.

[apoca]

il doit forcément y avoir une formule qui permet ça mais je ne l'ai trouvée nulle part.

Non…
Ce n'est pas possible avec Numbers…

[baron]

ça prend un temps fou et surtout, à chaque nouvelle commande, il faut recommencer.

Si tu crées une feuille récapitulative au bout de ton classeur et que tu insères avant une nouvelle feuille (par duplication de la feuille précédente) pour chaque commande, il te suffit de rajouter dans ton récapitulatif la référence de la dernière feuille insérée pour avoir un total à jour.
(Il me semble avoir compris que pour le moment, tu as une cellule récapitulative sur chaque feuille… Si c'est ce que tu veux, tu peux aussi faire comme ci-dessus et puis sur chaque feuille avoir simplement une cellule qui affiche le contenu de la cellule récapitulative tout au bout du classeur. Ainsi tu n'as qu'une formule à mettre à jour.)

@ apoca : merci d'avoir confirmé ce que je soupçonnais mais n'osais affirmer.

[Lohuli]

il doit forcément y avoir une formule qui permet ça mais je ne l'ai trouvée nulle part.

Non…
Ce n'est pas possible avec Numbers…

C'est tout bonnement incroyable pour ne pas dire inadmissible, ça me semble une fonction absolument essentielle

ça prend un temps fou et surtout, à chaque nouvelle commande, il faut recommencer.

Si tu crées une feuille récapitulative au bout de ton classeur et que tu insères avant une nouvelle feuille (par duplication de la feuille précédente) pour chaque commande, il te suffit de rajouter dans ton récapitulatif la référence de la dernière feuille insérée pour avoir un total à jour.
(Il me semble avoir compris que pour le moment, tu as une cellule récapitulative sur chaque feuille… Si c'est ce que tu veux, tu peux aussi faire comme ci-dessus et puis sur chaque feuille avoir simplement une cellule qui affiche le contenu de la cellule récapitulative tout au bout du classeur. Ainsi tu n'as qu'une formule à mettre à jour.)

Pardon baron mais je n'ai pas compris.
J'ai actuellement un fichier numbers qui comporte 35 feuilles :

• Une Liste de pointage indépendante
• Une feuille 0 matrice, que je duplique pour créer chaque nouvelle commande
• Une feuille Total qui comprend les totaux de tous les articles en utilisant la méthode décrite plus haut pour les
• 29 premières feuilles qui sont totalisées dans la feuille Total
• 3 feuilles avec les nouvelles commandes totalisées nulle part

Est-ce qu'avec ta méthode je peux faire ce que je veux.
Si oui, peux-tu m'expliquer de nouveau comment ?

Merci à tous les deux en tout cas.

[Guest_JacqR_*]

Bonsoir,

Ça fonctionne mais l'inconvénient est quand une commande se rajoute je dois tout recommencer.

Je ne crois pas que vous avez besoin de tout recommencer.

Supposons que vous ajouter la feuille "30" et la feuille "31" :

Il suffit d'ajouter "31::invoice::A12+30::invoice::A12+" au début de la formule dans la première cellule, tu valide.
Après tu tire jusqu'à la dernière cellule qui contient cette formule pour mettre à jour les autres formules.

[baron]

C'est exactement ça que je tentais d'expliquer.

[Lohuli]

Bonsoir,

Ça fonctionne mais l'inconvénient est quand une commande se rajoute je dois tout recommencer.

Je ne crois pas que vous avez besoin de tout recommencer.

Supposons que vous ajouter la feuille "30" et la feuille "31" :

Il suffit d'ajouter "31::invoice::A12+30::invoice::A12+" au début de la formule dans la première cellule, tu valide.
Après tu tire jusqu'à la dernière cellule qui contient cette formule pour mettre à jour les autres formules.

C'est, en exagérant, ce que j'appelle "tout recommencer" car en fait je ne peux pas tirer toutes les cellules à la fois. Ignorant que j'aurais ce problème, ma mise en page regroupe des articles par catégories et l'entête de chacune d'elle occupe une ligne avec toutes les cellules regroupées, donc je ne peux tirer que quelques cellules à la fois et donc je dois répéter l'opération pour chaque groupe de cellule. Je n'en reviens toujours pas que cette formule soit impossible à faire !!
Bref, merci quand même

[Guest_JacqR_*]

Bonjour,

C'est, en exagérant, ce que j'appelle "tout recommencer" car en fait je ne peux pas tirer toutes les cellules à la fois. Ignorant que j'aurais ce problème, ma mise en page regroupe des articles par catégories et l'entête de chacune d'elle occupe une ligne avec toutes les cellules regroupées, donc je ne peux tirer que quelques cellules à la fois et donc je dois répéter l'opération pour chaque groupe de cellule.

Ok,

Au lieu de le faire manuellement, c'est possible de modifier ces formules par un script AppleScript
Voici un exemple, fonctionne sur Numbers version 3.1 ou plus récents.

Code

-- EX ***   cela ajoutera les cellules des nouvelles feuilles (31 et 30 par exemple) --> 31::invoice::A12+30::invoice::A12
property oldCellRef : ""
set FormulaRange to "D:E" -- colonnes qui contient des formules à modifier
set sheetName to "Total" -- le nom de la feuille dont il faut modifier les formules
set tableIndex to 1 -- l'index du tableau dans la feuille dont il faut modifier les formules
set tableName to "invoice" -- invoice est le nom des tableaux qui contient des articles

tell application "Numbers"
    tell document 1
        set x to sheets whose name is not sheetName
        set sheetNames to {}
        repeat with i in x -- on récupère les noms des feuilles, si la feuille contient le tableau "Invoice"
            if exists table tableName of i then set end of sheetNames to name of i
        end repeat
        set myRange to range FormulaRange of table tableIndex of sheet sheetName
        set tc to count cells of myRange
        set toAdd to ""
        repeat with i from 1 to tc
            set fonction to formula of cell i of myRange
            if fonction is not missing value then
                if toAdd = "" then -- premièrement, on cherche ce qui manque dans la formule (par rapport aux feuilles ajoutées dans le document)
                    set toAdd to my getChange(fonction, sheetNames, tableName)
                    if toAdd is "" then exit repeat -- quitte le script, parce qu'il n'y a aucun changement à faire
                    set newForm to fonction & toAdd
                else -- après on change seulement l'addresse de la cellule dans le texte de la  variable "toAdd"
                    set newForm to my upadteForm(fonction, toAdd, tableName)
                end if
                if newForm is not "" then set value of cell i of myRange to newForm
            end if
        end repeat
    end tell
    display dialog "Terminé"
end tell

on getChange(f, L, t)
    if ("::" & t & "::") is not in f then return ""
    set {tid, text item delimiters} to {text item delimiters, {"::" & t, "+"}}
    set l1 to text items of f
    set text item delimiters to "" --tid
    set ajout to ""
    set noms to {}
    repeat with j from 1 to (count l1) by 2 -- on récupére les noms des feuilles dans la première fonction
        set thisN to item j of l1
        if j = 1 then set thisN to text 2 thru -1 of thisN
        set end of noms to thisN
    end repeat
    set cellRef to item 2 of l1
    repeat with j in L -- on garde les noms des feuilles qui ne sont pas dans la fonction
        if contents of j is not in noms then set ajout to ajout & "+" & j & "::" & t & cellRef
    end repeat
    set oldCellRef to cellRef
    return ajout -- les références à ajouter à la première formule
end getChange

on upadteForm(f, s, t) -- on modifie le texte qui a été ajouter à la première formule, on remplace le nom de la cellule. EX "::A12" sera remplacer par "::A13"
    if ("::" & t & "::") is not in f then return ""
    set {tid, text item delimiters} to {text item delimiters, {"::" & t, "+"}}
    set cellRef to text item 2 of f
    set text item delimiters to oldCellRef
    set L to text items of s
    set text item delimiters to cellRef
    set s to L as text
    set text item delimiters to "" --tid
    return f & s
end upadteForm

Ce script récupère tous les noms des feuilles dont la table "invoice" est existante.
Il comparera ces noms avec la première formule dans la colonne "D" pour ne garder que les noms des feuilles ajoutées au document, le résultat sera par exemple (si les nouvelles feuilles sont "30" et "31") --> 31::invoice::A12+30::invoice::A12
Bien entendu que s'il n'y pas de nouvelle feuille, le script quittera sans modifier les formules.

Après cela, le script modifiera les autres formules dans les colonnes "D" et "E", si la cellule contient une formule bien attendu

Si vous voulez tester le script (le faire sur une copie de votre document, et le document doit-être ouvert dans Numbers), vous devez modifier les quatre lignes après la ligne property oldCellRef : "" dans le script, le nom de la feuille, la ou les colonnes des formules (doit-être consécutive), le nom du tableau et l'index du tableau selon votre document.

Edition, pour les colonnes
si c'est pour une seule colonne, D par exemple, cela doit-être "D:D" dans le script
Pour les colonnes D, E et F par exemple, cela doit-être "D:F" dans le script

Ce message a été modifié par JacqR - 15 May 2015, 14:46.

[Lohuli]

Ouh là, là.
Je vais regarder ça ce week-end car je ne suis pas très fort en Applescript (il m'arrive de ne pas réussir à renommer simplement des fichiers :-p )
Merci en tout cas de tenter de m'aider, c'est très sympa.

[trouspinette]

Une petite recherche m'a permis de trouver :

Google: https://www.google.fr/?gws_rd=ssl#q=sum%20in%20different%20sheets%20in%20apple%20numbers

Entre autres : https://discussions.apple.com/thread/6474083

[Lohuli]

Une petite recherche m'a permis de trouver :

Google: https://www.google.fr/?gws_rd=ssl#q=sum%20in%20different%20sheets%20in%20apple%20numbers

Entre autres : https://discussions.apple.com/thread/6474083

Merci trouspinette,
je n'avais pas fait de recherche en anglais.
Je vais voir si je peux comprendre et je reviens vers vous si ça fonctionne.

En fait, si je ne m'abuse, ça ne permet pas de faire une somme de la case A12 des feuilles 1 à 35 mais simplement de les additionner manuellement comme je fais donc

Ce message a été modifié par Lohuli - 15 May 2015, 21:19.

[jumera]

Salut
Il y a quelque chose que je ne comprends pas

Comment peux tu écrire dans une cellule une formule
qui fait référence à une cellule d'une feuille qui n'existe pas ?
(puisque tu rajoute des feuilles au fur et à mesure)

C'est tout bonnement incroyable pour ne pas dire inadmissible, ça me semble une fonction absolument essentielle

Tu connais un tableur qui fait ça ?
Lequel et comment ?

[Lohuli]

Salut
Il y a quelque chose que je ne comprends pas

Comment peux tu écrire dans une cellule une formule
qui fait référence à une cellule d'une feuille qui n'existe pas ?
(puisque tu rajoute des feuilles au fur et à mesure)

Bonsoir jumera,

les cellules existent, au moins les 32 premières, pour lesquelles j'aimerais une formule qui serait plus facile à reproduire pour les nouvelles feuilles car en effet, tu as raison, ce n'est pas anormal de ne pouvoir faire une formule avec des feuilles qui n'existent pas encore.

C'est tout bonnement incroyable pour ne pas dire inadmissible, ça me semble une fonction absolument essentielle

Tu connais un tableur qui fait ça ?
Lequel et comment ?

Si je le savais, je l'utiliserais.

[Guest_JacqR_*]

Bonjour,

les cellules existent, au moins les 32 premières, pour lesquelles j'aimerais une formule qui serait plus facile à reproduire pour les nouvelles feuilles car en effet, tu as raison, ce n'est pas anormal de ne pouvoir faire une formule avec des feuilles qui n'existent pas encore.

C'est tout bonnement incroyable pour ne pas dire inadmissible, ça me semble une fonction absolument essentielle

Tu connais un tableur qui fait ça ?
Lequel et comment ?

Si je le savais, je l'utiliserais.

C'est possible avec Excel :

La formule sera =SOMME('1:vide'!A12)
Cela calculera toute les cellules A12 à partir de la feuille nommée "1" jusqu'à la feuille nommée "vide" (il suffit de masquer la feuille "vide").

Pour que cela fonctionne, les feuilles à calculer doivent-être consécutives.

Donc, il suffit de placer les feuilles à exclure avant la feuille "1" ou après la feuille "vide".
Quand on veut insérer une nouvelle feuille dont on veut additionner la cellule, il suffit de l'insérer entre la feuille "1" et la feuille "vide"

[Lohuli]

Merci beaucoup JacqR

[KOENIG Yvan]

Désolé de ne pas avoir vu ce fil plus tôt.

Tout se passe dans une table de la feuille utilisée pour effectuer les calculs
Dans la colonne A à partir de A2 on insère les noms de feuilles.
J'ai testé avec Feuille 1, Feuille 2 …
Dans la cellule B2 insérer la formule :
=ADRESSE(12;1;1;1;A2&"::Tableau 1")
Qui crée l'adresse de la cellule A12 de la table "Tableau 1" de la feuille dont le nom est en A2
Recopier vers le bas

Dans la cellule C2, insérer la formule :
=SI.ERREUR(INDIRECT(B2;style-adresse);0)
qui extraira le contenu de la cellule A12 de la table "Tableau 1" de la feuille dont le nom est en A2
Recopier vers le bas.
Lorsque la formule tentera d'extraire la valeur d'une feuille inexistante, grâce à SI.ERREUR la formule donnera 0.

En supposant que le rang 1 est un rang d'en-tête, insérer en C1 la formule :
=SOMME©

Et voilà, vous obtenez le total demandé.

Yvan KOENIG (VALLAURIS, France) mardi 26 mai 2015 21:26:08