Automator pour convertir automatiquement les .cwk en .doc ?

[LC475]

J'ai environ 2300 documents AppleWorks 5 que j'aimerais convertir au format Word (ou OpenOffice, mais ça me semble plus compliqué encore).


Idée 1 : MacLinkPlus sait faire cette conversion, mais il faut lui indiquer quels sont les fichiers à traiter et les range tous dans un dossier.

Ce que j'aimerais, c'est créer un script qui :
1/ détecte tous les documents AppleWorks
2/ lance MacLinkPlus pour convertir ces documents
3/ place les éléments convertis au même endroit que les fichiers d'origine



Idée 2 : Word 2004 sait également lire les fichiers AppleWorks 5.

Ce serait peut-être plsu simple de créer un script demandant d'ouvrir tous les fichiers AppleWorks et de les enregistrer au format Word.




Alors si quelqu'un pouvait m'indiquer comment je pourrais faire cela avec Automator, ça m'arrangerait bien !
Pour info, mon Mac fonctionne avec MacOS 10.5.6.

Merci

[Guest_EricaL**_*]

Bonjour,

Vous voulez tous les convertir dans le format ".doc" ?

Il n'y a pas d'actions dans Automator pour faire ce que vous demandez.
Par contre, c'est facilement faisable en AppleScript.

Si vous voulez bien, donnez-moi les extensions des fichiers "AppleWorks" à convertir avec "Microsoft Word", et je pourrais vous faire un script.

[LC475]

Oui, je veux tous les convertir au format Word ou OpenOffice.
Comme ces fichiers ont été créés avec un Mac en OS9, il ne comportent pas d'extension.
Voilà les informations données par un fichier pris au hasard :


NB: J'ai retrouvé mon installeur d'AppleWorks6 mais j'aimerais tout de même passer à un format de fichier plus "ouvert".

[Guest_EricaL**_*]

Bonjour,

Oui, je veux tous les convertir au format Word ou OpenOffice.
Comme ces fichiers ont été créés avec un Mac en OS9, il ne comportent pas d'extension.

Ici sur Leopardi, les fichiers de traitement de texte "AppleWorks" ne s'ouvrent pas dans Word 2004, mais ça fonctionne sur Tiger.
Ici les fichiers créés par le tableur "AppleWorks" ne s'ouvrent pas dans Excel 2004, ni dans Word 2004, sur Leopard et Tiger

Est-ce qu’il faut aussi convertir les fichiers "AppleWorks" autres que ceux créés par le traitement de texte ?

Si vous pouvez les ouvrir dans Word, essaie le premier script sinon essaie le deuxième script.

Les scripts fonctionneront seulement si vos fichiers du dossier qui contient les fichiers "AppleWorks" ont été indexés par Spotlight.
Le script recherchera dans tous les sous dossiers du dossier sélectionné tous les fichiers du traitement de texte "AppleWorks".

Si Spotlight n'a pas indexé ces fichiers, il faudra faire un script qui recherchera le file type "CWWP" avec le Finder, beaucoup plus lent.
Est ce qu'il faut rechercher dans tous les sous dossiers ?
Si oui, est ce que le dossier contient plus de 10000 éléments ?


Premier script :

Code

set F to (choose folder with prompt "Sélectionner le dossier qui contient les fichiers \"AppleWorks\"")
set dossier_de_recherche to quoted form of POSIX path of F
save_CWK_to_Doc(do shell script " mdfind  -onlyin " & dossier_de_recherche & " \"kMDItemFSTypeCode==1129797456\"") -- 1129797456 = file type CWWP


on save_CWK_to_Doc(r)
    script o
        property Ces_fichiers : paragraphs of r
    end script
    set tc to (count o's Ces_fichiers)
    set fichiers_erreur to {}
    tell application "Microsoft Word" to set nbr to open format of file converter "AppleWorks 5 & 6"
    
    if tc > 0 then repeat with i from 1 to tc
        set ceFichier to (POSIX file (item i of o's Ces_fichiers)) as string
        tell application "Microsoft Word" to try
            open file name ceFichier file converter nbr with read only without confirm conversions
            tell front document
                save as file name (ceFichier & ".doc") file format format document with embed truetype fonts
                close
            end tell
        on error
            set end of fichiers_erreur to (ceFichier & return)
        end try
    end repeat
    if fichiers_erreur is not {} then
        tell application "TextEdit"
            activate
            make new document with properties {text:"Ces fichiers n'ont pas été traités :" & return & return & fichiers_erreur}
        end tell
    end if
end save_CWK_to_Doc

Il faudra modifier dans le script, le nom du convertisseur "AppleWorks 5 & 6" par le nom localisé du convertisseur que vous utilisez.
Pour avoir le nom exact, exécuter ce script, copier/coller le titre du convertisseur que vous utilisez.

Code

tell application "Microsoft Word" to format name of every file converter

Important : si lors de l'ouverture de Word , une fenêtre de dialogue s'ouvre, lancer Word et fermer cette fenêtre avant d'exécuter le script.



Deuxième script :

Code

set F to (choose folder with prompt "Sélectionner le dossier qui contient les fichiers \"AppleWorks\"")
set dossier_de_recherche to quoted form of POSIX path of F
save_CWK_to_Doc(do shell script " mdfind  -onlyin " & dossier_de_recherche & " \"kMDItemFSTypeCode==1129797456\"") -- file type CWWP


on save_CWK_to_Doc(r)
    script o
        property Ces_fichiers : paragraphs of r
    end script
    set tc to (count o's Ces_fichiers)
    set fichiers_erreur to {}
    
    if tc > 0 then repeat with i from 1 to tc
        set ceFichier to (POSIX file (item i of o's Ces_fichiers)) as string
        tell application "AppleWorks 6" to try
            open (ceFichier as alias)
            tell front document
                save in file (ceFichier & ".doc") as file type "W8BN" using translator "Word Mac 98, 2001 document"
                close saving no
            end tell
        on error
            set end of fichiers_erreur to (ceFichier & return)
        end try
    end repeat
    if fichiers_erreur is not {} then
        tell application "TextEdit"
            activate
            make new document with properties {text:"Ces fichiers n'ont pas été traités :" & return & return & fichiers_erreur}
        end tell
    end if
end save_CWK_to_Doc

Il faudra modifier dans le script, le nom du convertisseur "Word Mac 98, 2001 document" par le nom localisé du convertisseur que vous utilisez .
Pour avoir le nom exact, exécuter ce script, copier/coller le titre du convertisseur que vous utilisez.

Code

tell application "AppleWorks 6" to export translators

Ce message a été modifié par EricaL** - 6 Mar 2009, 08:56.

[LC475]

Un grand merci pour tout ! Vraiment


Est-ce qu’il faut aussi convertir les fichiers "AppleWorks" autres que ceux créés par le traitement de texte ?
Non, ce ne sont que des documents texte, contenant parfois des images.
J'ai fait un test, celles au format png disparaissent, mais tant pis.


Est ce qu'il faut rechercher dans tous les sous dossiers ?
Si oui, est ce que le dossier contient plus de 10000 éléments ?
Non, ce n'est pas utile car tout est rangé dans un dossier de 25000 éléments qui contient des sous-dossiers et que je peux donc, pour faciliter la chose, regrouper en trois ou quatre dossiers temporaires de moins de 10000 éléments.


Ici sur Leopardi, les fichiers de traitement de texte "AppleWorks" ne s'ouvrent pas dans Word 2004, mais ça fonctionne sur Tiger.
Je n'ai pas testé, mais c'est curieux : une explication ?
Est-ce préférable que j'effectue la conversion sur un Mac en 10.4 ?


Les scripts fonctionneront seulement si vos fichiers du dossier qui contient les fichiers "AppleWorks" ont été indexés par Spotlight.
Comment vérifier qu'ils ont été indexés ?
Si je fais une recherche par contenu et que des fichiers AppleWorks apparaissent dans les résultats, c'est bon ?


Alors si j'ai bien compris :
Comme je n'ai pour le moment pas installé Word 2004, il faudrait que j'utilise le second script qui recourt à AppleWorks 6.
Aucune utilité à MacLinkPLus ?
Le script demande d'ouvrir les documents AppleWorks un par un et de les enregistrer au format Word.


Encore une fois, merci de prendre du temps pour m'aider

[Guest_EricaL**_*]

Bonjour,

Ici sur Leopardi, les fichiers de traitement de texte "AppleWorks" ne s'ouvrent pas dans Word 2004, mais ça fonctionne sur Tiger.
Je n'ai pas testé, mais c'est curieux : une explication ?

Je n'ai de réponse précise sur le problème, mais ça à rapport avec l'OS.

Est-ce préférable que j'effectue la conversion sur un Mac en 10.4 ?

Ça fonctionne sur Tiger que s'il n'y a pas d'images sinon le fichier ne s'ouvre pas.
Donc le premier script ne doit pas être utilisé, le nombre de fichiers non traité risque d'être trop élevé.

Comment vérifier qu'ils ont été indexés ?
Si je fais une recherche par contenu et que des fichiers AppleWorks apparaissent dans les résultats, c'est bon ?

Oui.

Alors si j'ai bien compris :
Comme je n'ai pour le moment pas installé Word 2004, il faudrait que j'utilise le second script qui recourt à AppleWorks 6.

Oui, si la perte de certaines images n’est pas importante lors de la conversion.

Le script demande d'ouvrir les documents AppleWorks un par un et de les enregistrer au format Word.

Il suffit de vérifier le nom du translator "Word Mac 98, 2001 document" et de modifier le nom dans le script en conséquence, parce qu'ici j'ai la version anglaise, il se peut que le nom ne soit pas exactement pareil dans la version française.
Le script va ouvrir un dialogue vous demandant de sélectionner le dossier qui contient les fichiers "AppleWorks".
Après, tout se fait automatiquement.
La commande mdfind recherchera tous les fichiers ayant un (file type "CWWP") dans le dossier sélectionné et dans tous ces sous dossiers.

Aucune utilité à MacLinkPLus ?

Si vous avez la version 12.0 ou + de "MacLinkPlus Deluxe", il est scriptable.

Mais je n'ai pas cette application et il n'est pas disponible en version d'essai.
Donc, je n'ai pas la syntaxe exacte pour ces deux commandes (open et save) dans son dictionnaire AppleScript.

Normalement MacLinkPlus aurait installé des scripts d'exemple dans le dossier "/Bibliothèque/Scripts/MacLinkPlus Scripts/Scripts Snippets/" sur le disque de démarrage ou dans ta maison.
Fait une recherche dans ces dossiers, si tu trouves un script ayant comme nom "Translate Folder Action", post les lignes du script et je pourrais modifier mon script pour convertir les fichiers avec l'application "MacLinkPlus Deluxe"

Ce message a été modifié par EricaL** - 9 Mar 2009, 02:51.

[LC475]

OK, merci beaucoup. Je n'ai actuellement pas beaucoup de temps, je m'en occuperai à Pâques car je pense qu'il est préférable de travailler sur des copies !

C'est vraiment sympa de m'avoir consacré du temps

[LC475]

J'ai testé le script : tout fonctionne bien, mais il y a un souci à l'ouverture des fichiers (avec Word 2008 ou OpenOffice 3.1) qui ne semblent contenir que : · BOBO ? k»? J S . 7 k…` ?? X±
k…X
Pourtant en exportant un fichier individuellement, il n'y a aucun souci.
J'essaierai à nouveau en réinstallant un système 10.4...

Mais merci

[sucellus]

J'ai testé le script : tout fonctionne bien, mais il y a un souci à l'ouverture des fichiers (avec Word 2008 ou OpenOffice 3.1) qui ne semblent contenir que : · BOBO ? k»? J S . 7 k…` ?? X±
k…X
Pourtant en exportant un fichier individuellement, il n'y a aucun souci.
J'essaierai à nouveau en réinstallant un système 10.4...

Mais merci

Bonjour

Va voir cette adresse si ça peut donner des idées.

http://idisk.me.com/koenigyvan-Public?view=web

Scripts_for_AppleWorks / AW batch BOBO2Office8.applescript.zip

@+

[LC475]

C'est sympa mais il y a plus de 2000 fichiers à modifier et j'aimerais qu'ils soient tous ouverts, enregistrés au format .doc et que l'original soit détruit (bien sûr, je fais une sauvegarde avant, afin de pouvoir récupérer mes fichiers au cas où il y aurait un souci).
Je ne sais pas si Office 2008 est censé ouvrir les .cwk ou si seule la version 2004 le pouvait, mais sinon, je dispose de MacLinkPlus 16.


Edit : Orthographe

Ce message a été modifié par LC475 - 3 Aug 2009, 21:04.

[LC475]

Deuxième script :

Code

set F to (choose folder with prompt "Sélectionner le dossier qui contient les fichiers \"AppleWorks\"")
set dossier_de_recherche to quoted form of POSIX path of F
save_CWK_to_Doc(do shell script " mdfind  -onlyin " & dossier_de_recherche & " \"kMDItemFSTypeCode==1129797456\"") -- file type CWWP


on save_CWK_to_Doc(r)
    script o
        property Ces_fichiers : paragraphs of r
    end script
    set tc to (count o's Ces_fichiers)
    set fichiers_erreur to {}
    
    if tc > 0 then repeat with i from 1 to tc
        set ceFichier to (POSIX file (item i of o's Ces_fichiers)) as string
        tell application "AppleWorks 6" to try
            open (ceFichier as alias)
            tell front document
                save in file (ceFichier & ".doc") as file type "W8BN" using translator "Word Mac 98, 2001 document"
                close saving no
            end tell
        on error
            set end of fichiers_erreur to (ceFichier & return)
        end try
    end repeat
    if fichiers_erreur is not {} then
        tell application "TextEdit"
            activate
            make new document with properties {text:"Ces fichiers n'ont pas été traités :" & return & return & fichiers_erreur}
        end tell
    end if
end save_CWK_to_Doc

Il faudra modifier dans le script, le nom du convertisseur "Word Mac 98, 2001 document" par le nom localisé du convertisseur que vous utilisez .
Pour avoir le nom exact, exécuter ce script, copier/coller le titre du convertisseur que vous utilisez.

Code

tell application "AppleWorks 6" to export translators

J'ai fait un nouvel essai et ça a très bien fonctionné : un grand grand merci

[Guest_EricaL**_*]

Bonsoir,

J'ai fait un nouvel essai et ça a très bien fonctionné : un grand grand merci

Super , content que ça fonctionne.

[LC475]

C'était vraiment sympa de prendre du temps pour écrire le script !

[macosreparation]

Bonjour, comment allez vous ?
Cela fait un bout de temps que vous avez écrit sur le sujet Automator cwk en doc, .
je voulais savoir s'il était possible de fair la meme chose avec du MacWrite 2, j'ai réussi a retrouver le programme, et j'ai pas mal de fichier que j'aimerai convertir en TXT, merci d'avance

[Pascal 77]

Idée 2 : Word 2004 sait également lire les fichiers AppleWorks 5.

Mais Word 2004 n'a pas besoin d'automator, il dispose du VBA, rien de plus facile que d'enregistrer une macro convertissant un fichier et allant le ranger ailleurs, puis d'écrire autour une boucle comptant le nombre d'éléments à traiter, pour automatiser le reste !