Version imprimable du sujet

-- Création d'un répertoire sur le bureau pour stocker les nouveaux répertoires qui seront créés

display dialog "Entrez le nom du dossier à créer :" default answer "" buttons {"Annuler", "Continuer"} default button 2
set mon_dossier to text returned of the result

tell application "Finder" to make new folder at desktop with properties {name:mon_dossier}

--Préparation du chemin du répertoire pour la sauvegarde des nouveaux répertoires

set mon_chemin to (POSIX file (POSIX path of (path to desktop) & mon_dossier))

--Travail dans le Fichier Excel

tell application "Microsoft Excel"
    tell active sheet
        
        --Définition du nombre de répertoires à créer
        set lastRowNum to first row index of (get end (cell 1 of row (count rows)) direction toward the top)
        
        --Boucle qui lit pour chaque ligne les cellules Excel et écrit le répertoire
        repeat with N from 1 to lastRowNum
            
            --Lecture des cellules A(N) et B(N) dans le fichier Excel
            set mon_titre to ((get value of range ("A" & N)) & (get value of range ("B" & N))) as string
            
            --Création du répertoire avec le nom définit ci-dessus
            tell application "Finder" to make new folder at folder mon_chemin with properties {name:mon_titre}
            
        end repeat
        
    end tell
end tell