comment supprimer les doublons ds Itunes ?

[Guest_EricaL**_*]

Bonjour,

j'aimerais supprimer les doublons seulement s'ils ont exactement le même nom, le même album, le même artiste, pourquoi pas le même numéro de piste (pour l'instant rien de nouveau), mais surtout la même taille et la même durée.

Voici les lignes modifiées du script dans le message #37

Code

        tell item i of o's Les_tracks to set {titre, Lartiste, Lalbum, T_ID, No_piste, temps, taille} to {name, artist, album, database ID, track number, time, size}
        repeat with k from (i + 1) to total --ceci va enlever tous les doublons à la suite ayant le même titre,  même album, no de piste, taille, durée
            tell item k of o's Les_tracks to set {titre2, Lartiste2, Lalbum2, T_ID2, No_piste2, temps2, taille2} to {name, artist, album, database ID, track number, time, size}
            if titre2 is titre and Lartiste is Lartiste2 and Lalbum is Lalbum2 then
                if T_ID is not T_ID2 then
                    if No_piste = No_piste2 and temps = temps2 and taille = taille2 then

Information : la taille en AppleScript (size) est le nombre exact d'octets du fichier et non celui affiché dans la colonne "Taille" d'iTunes .
Inconvénient : la taille en Mo peut être identique dans la colonne, mais il est possible que la taille ne soit pas identique en octets, donc le doublon ne sera pas supprimé.

Exemple : je duplique un morceau, je l'ajoute dans iTunes, le size est identique.
Je supprime la pochette du morceau dupliqué, je copie la pochette du morceau original, je la colle dans le morceau dupliqué, la taille en octets n'est plus identique (morceau original 9209754 octets, morceau dupliqué 9213562 octets).

[pluchon]

nickel merci !

[Gohu]

Oui ça marche à la perfection, c'est génial ! Merci beaucoup !!

[pmartignier]

Merci çà tourne en ce moment....

attention çà plante dès qu'il y a des radios web, mais si on fait le tri des radios avant (flux) çà passe nickel!

c'est hallucinant qu apple n'ait pas incorporé un tel script de base ... mais bon y reste tjs la bidouille merci !!!!!

[phiiris]

Un grand merci pour le script, ça me sauve vraiment : 14000 titres dans la série des doublons suite à des (très) mauvaises manipulations dédoublés détriplés, déquadruplés en un minimum de temps. Super.

Phiiris.

[ptitsuisse]

Hello !

...j'suis assez nouveau chez mac, et j'rencontre un prob' avec le script...

...primo, j'arrive pas à le copié-collé dans l'éditeur...alors j'ai écrit ligne par ligne...mais je sais pas pk, il me met qu'il y a une erreure dedans...
...alors j'essaye de le mettre ici, mias 2ème couac, impossible de le joindre...

pour info, j'ai fait donc un mix du message 37 et 61

...si jamais mon mail : ed.mon ( at ) hotmail . fr

...merci d'avance pour votre aide ! =)

[Guest_EricaL**_*]

Bonsoir,

...primo, j'arrive pas à le copié-collé dans l'éditeur...alors j'ai écrit ligne par ligne...mais je sais pas pk, il me met qu'il y a une erreure dedans...

À partir de quel navigateur copier vous le texte ?
À partir de quel éditeur coller vous le texte ?
Quel est le texte du message d'erreur ?
Quelle est la version d'iTunes ?
Quelle est la version de Mac OS X ?

Le mix du script dans le message 37 et du script dans le message 61 donnerait :

Code

script o
    property Les_tracks : missing value
end script
set reussi to 0
set non_reussi to 0

display dialog "                             Attention !" & return & return & "Ce script va supprimer tous les doublons" & return & "ayant le même titre, le même album" & return ¬
    & "et le même numéro de piste" & return & "à partir des pistes sélectionnées" with title "Supprimer des  doublons" buttons {"Quitter le script", "Continuer"} cancel button "Quitter le script"

set i to 1
tell application "iTunes"
    set o's Les_tracks to selection
    if o's Les_tracks is {} then error "Vous devez sélectionner des pistes avant d'exécuter ce script."
    
    set total to (count o's Les_tracks)
    repeat while i < total
        tell item i of o's Les_tracks to set {titre, Lartiste, Lalbum, T_ID, No_piste, temps, taille} to {name, artist, album, database ID, track number, time, size}
        repeat with k from (i + 1) to total --ceci va enlever tous les doublons à la suite ayant le même titre,  même album, no de piste, taille, durée
            tell item k of o's Les_tracks to set {titre2, Lartiste2, Lalbum2, T_ID2, No_piste2, temps2, taille2} to {name, artist, album, database ID, track number, time, size}
            if titre2 is titre and Lartiste is Lartiste2 and Lalbum is Lalbum2 then
                if T_ID is not T_ID2 then
                    if No_piste = No_piste2 and temps = temps2 and taille = taille2 then
                        tell (get first track of library playlist 1 whose database ID is T_ID2)
                            set the_path to location
                            if my delete_file(the_path) then
                                delete --supprime de la bibliothèque
                                set reussi to reussi + 1
                            else
                                set non_reussi to non_reussi + 1
                            end if
                        end tell
                    end if
                else --même database id : supprime de la liste de lecture seulement , pas dans la  bibliotheque, ni sur le disque
                    delete item k of o's Les_tracks
                end if
            else
                exit repeat
            end if
        end repeat
        set i to k -- mets la variable (i) à l'index de l'élément dont le titre est différent
    end repeat
end tell
display dialog "" & reussi & " doublons supprimés." & return & non_reussi & " doublons non supprimés"

on delete_file(t_file)
    try
        tell application "Finder" to delete t_file
        return true
    end try
    return false
end delete_file

Ce message a été modifié par EricaL** - 3 Apr 2010, 01:13.

[ptitsuisse]

Re'

Merci beaucoup pour ta réponse, je ne sais pas pourquoi sa n'allai pas, en faite, j'ai redemarré mon Mac après 2 semaines non-stop, et là sa marchai...je sais pas si c'était un soucis avec la mémoire qui étaient pleine...enfin bref' maintenant ça fonctionne à la perfection !

Merci beucoup pour ta réponse.

(et pour répondre à ta question, j'ai essayé depuis plusieurs naviguateur, Chrome & Safari, je le collai sur l'Editeur AppleScript, le texte je ne m'en souviens plus exactement, pi je tourne avec ITunes9.0.3 (15) pi Mac OS X 10.6.2 qui tourne sur un Imac 21.5 pouces avec 3.6 Ggz Intel Core II Duo / 4 Go 7 1067 MHz)

Voili voilà, merci encore pour ta réponse rapide ! ^^

[Fafone]

Ok mais plus compliqué maintenant:

En général pour chaque morceau j'ai 4 doublons dont 3 qui ne marche pas (une sombre histoire )

comment faire disparaitre les doublons et ne garder que les morceaux qui marchent finalement?

Un grand merci à mon futur sauveur!

[LooKman]

Merci beaucoup, je viens d'appliquer ton script sur 12342 doublons… Je ne sais plus combien de Go ca fait mais un truc comme 60 Go.
Je dois avouer que l'exécution du script n'est pas terminé ( parce qu'il en faut du temps -Normal-) mais c'est en de bonne voie. Il faut dire que je sauvegarde ma bibliothèque par copier/coller des dossiers musiques ( sur un DD ) et iTunes depuis la première version d'itunes.

[Cosmoboy]

Bonjour,

Je relance désolé :s j'ai lancé le script du message 67 avec les morceaux selectionnés et triés par ordres alphabétiques mais rien n'y fait il n'en reconnait aucun

iTunes 9.2 , 10.6.4

Merci!

[Guest_EricaL**_*]

Bonjour,

Je relance désolé :s j'ai lancé le script du message 67 avec les morceaux selectionnés et triés par ordres alphabétiques mais rien n'y fait il n'en reconnait aucun

Le script du message 67 est très restrictif, la taille (nombre d'octets) doit être identique.
Ce qui veut dire que le même fichier à été importé deux fois, si le morceau ne provient pas de la même source, la taille du fichier ne sera jamais la même.

Essaie le script du message#37.
Ou le script du message#31.

[de_Montmirail]

Le script fonctionne à merveille, c'est super méga génial ! merci beaucoup

[loase]

Bonjour,
je crois avoir un peu le meme probleme que celui decrit au message 69.
Pour repondre a un probleme de place sur le dd du mac, j'avais mis toute ma liste de lecture sur un dd externe Time Capsule.
A la fin de garantie de l'ordinateur, j'ai changé son dd et ai transféré toute la liste sur le Mac.
Probleme : suite a un probleme de sauvegarde, je me retrouve avec beaucoup de message en double (quelques uns en triple) mais dont le double, s'il semble avoir la meme taille, ne renvoie a rien puisque iTunes le cherche sur l'ancien serveur. Impossible donc de lire le fichier en cliquant dessus.
J'ai hier soir lancé le script decrit dans ces pages et qui fonctionne formidablement.
Le soucis, c'est qu'il elimine "l'un" des deux fichiers. Et souvent le valide...
J'ai donc reinstallé le fichier musique natif avec ses nombreux doubles cette nuit.
D'ou ma question : y a-t-il moyen de supprimer le bon fichier de la liste de lecture, soit celui qui est censé ne pas etre sur le dd du Mac mais sur l'ancien serveur et qui reste parfois sur la liste de lecture ?

Merci beaucoup de votre aide

l.

[Guest_EricaL**_*]

Bonjour,

D'ou ma question : y a-t-il moyen de supprimer le bon fichier de la liste de lecture, soit celui qui est censé ne pas etre sur le dd du Mac mais sur l'ancien serveur et qui reste parfois sur la liste de lecture ?

Avant de supprimer les doublons, il faut utiliser Super Remove Dead Tracks v2.2 pour enlever les morceaux qui n'existent plus.

[loase]

C'est beau, c'est grand, c'est fort. Un tres grand merci.
Il semble rester encore quelques doubles par ci par la... Je referai l'operation un peu plus tard.
Et j'avoue encore hesiter a vider la poubelle, des fois que...

Tiens une question encore : dans le langage iTunes, quelle est la difference entre un doublon et un double exact, puisque les deux propositions sont faites ?

l.

[Guest_EricaL**_*]

Tiens une question encore : dans le langage iTunes, quelle est la difference entre un doublon et un double exact, puisque les deux propositions sont faites ?

Afficher les éléments en double : il recherchera toutes les instances d’un même morceau du même artiste de n’importe quel album de votre collection.
Par exemple, un morceau peut être présent sur l’album de l’artiste mais aussi dans la bande originale d’un film.

Afficher les doubles exacts : il recherchera les différentes copies d’un même morceau, les tags nom, artiste et album sont pareils
Par exemple, vous avez importé le morceau deux fois par accident.

[woulf]

Juste un petit message pour dire: merci !
Ca fonctionne à merveille !

[mr-bob]

Salut,

J'ai la dernière version iTunes, et je ne trouve pas les "double-exacts", ou on trouve cette option ?

[radioman]

Salut,

J'ai la dernière version iTunes, et je ne trouve pas les "double-exacts", ou on trouve cette option ?

Touche "ALT" ...

[youpijoli]

Salut,

J'ai la dernière version iTunes, et je ne trouve pas les "double-exacts", ou on trouve cette option ?

Touche "ALT" ...

Oh! C'est génial comme truc les doubles exacts! Je connaissais pas.
Ça va me simplifier la vie, parce que les reprises des standards de Jazz, y'en un sacré paquet

[Jack the best]

Dans la vieille version de iTunes, ça fonctionne également, mais je ne vois pas comment les doublons trouvés pourraient être exacts ! La durée n'est pas la même !

[youpijoli]

Maintient alt et clique sur afficher les doublons.

[lekiv]

Je remonte le sujet : d'abord merci pour ce script qui me rend un grand service.

J'aimerais ajouter la possibilité de supprimer le fichier dont le nom de fichier est le plus long : mes doublons sont presque toujours dans le même dossier :

01 - Ah le petit vin blanc.mp3
01 - Ah le petit vin blanc 2.mp3

Le script supprime l'un ou l'autre aléatoirement, j'aimerais virer celui finissant par " 2.mp3" (qui n'est pas forcément le plus récent, suite aux copies de disques etc...)
Quel est le nom de la variable "nom de fichier", et comment tester sa longueur ?

Merci d'avance!

[Guest_EricaL**_*]

Je remonte le sujet : d'abord merci pour ce script qui me rend un grand service.

J'aimerais ajouter la possibilité de supprimer le fichier dont le nom de fichier est le plus long : mes doublons sont presque toujours dans le même dossier :

01 - Ah le petit vin blanc.mp3
01 - Ah le petit vin blanc 2.mp3

Voici le script qui supprime le doublon dont le nom du fichier est le plus long :

Code

script o
    property Les_tracks : missing value
end script

display dialog "Attention !" & return & return & "Ce script va supprimer tous les doublons dont le nom du fichier sera le plus long " & return & "à partir des pistes sélectionnées" with title "Supprimer des  doublons" buttons {"Quitter le script", "Continuer"} cancel button "Quitter le script"

set i to 1
tell application "iTunes"
    set o's Les_tracks to selection
    if o's Les_tracks is {} then error "Vous devez sélectionner des pistes avant d'exécuter ce script."
    
    set total to (count o's Les_tracks)
    repeat while i < total
        tell item i of o's Les_tracks to set {titre, Lartiste, Lalbum, T_ID, t_path} to {name, artist, album, database ID, location}
        repeat with k from (i + 1) to total --ceci va enlever tous les doublons à la suite ayant le même titre,  même album, no de piste
            tell item k of o's Les_tracks to set {titre2, Lartiste2, Lalbum2, T_ID2, t_path2} to {name, artist, album, database ID, location}
            if titre2 is titre and Lartiste is Lartiste2 and Lalbum is Lalbum2 then
                if T_ID is not T_ID2 then
                    if my verifieLongeurNOms(t_path as string, t_path2 as string) then -- vérifie la longeur du nom des deux fichiers
                        set {T_ID, t_path} to {T_ID2, t_path2}
                    end if
                    tell (get first track of library playlist 1 whose database ID is T_ID2)
                        delete --supprime de la bibliothèque
                        my delete_file(t_path2) --mets le fichier dans la corbeille
                    end tell
                end if
            else
                exit repeat
            end if
        end repeat
        set i to k -- mets la variable (i) à l'index de l'élément dont le titre est différent
    end repeat
end tell
activate (display dialog "Doublons dans Itunes, terminé")

on delete_file(t_file)
    try
        tell application "Finder" to delete t_file
    end try
end delete_file

on verifieLongeurNOms(n1, n2)
    set tid to text item delimiters
    set text item delimiters to ":"
    set x1 to length of last text item of n1
    set x2 to length of last text item of n2
    set text item delimiters to tid
    return x1 > x2
end verifieLongeurNOms

Ce message a été modifié par EricaL** - 23 Jan 2011, 19:23.

[qrull33]

bonjour,

merci pour ces merveilleux scripts que vous nous avez fourni!!!

mon problème a moi c est que lorsque je fais apparaitre mes doublons,je n arrive pas a effacer ceux ci avec le script.il son parfaitement identiques sauf pour les tailles.
il me faudrait un script qui fasse la différence entre les majuscules et le minuscules ,pour commencer.
puis un autres qui sélectionne la durée,par exemple garder la plus longue taille.

merci d avance a vous pour vos efforts

Ce message a été modifié par qrull33 - 28 Feb 2011, 18:56.

[T3zoual]

Bonjour à tous, je relance ce sujet, car à la suite de copies (réinstallation), j'ai en double de très nombreuses pistes.

Avec l'option 'doubles exacts', j'obtiens une liste de morceaux en doubles. Est-ce qu'il suffit de supprimer toutes les lignes de cette liste ?

A+
T3Z

[Guest_EricaL**_*]

Bonjour,

Si tu le fais manuellement, tu dois garder un morceau de chaque titre différent.

Si tu le fais par le script, tu sélectionnes tout, le script le fera automatiquement

[T3zoual]

Tu es sûr ? ... en comparant la liste des doublons, et la liste complète, iTunes semble n'affiche que les fichiers en double (par exemple s'il y a trois "morceaux" identiques, il n'en affiche que deux ...

D'où ma question : est-il possible de tout effacer. (la manipulation manuelle étant évidemment celle que je veux éviter, sur 20 000 titres, c'est un travail répétitif, long et fastidieux ...).

[Guest_EricaL**_*]

Tu es sûr ? ... en comparant la liste des doublons, et la liste complète, iTunes semble n'affiche que les fichiers en double (par exemple s'il y a trois "morceaux" identiques, il n'en affiche que deux ...

Je suis sûr pour toutes les versions que j'ai eu, mais c'est peut-être changé sur Lion.

J'ai fait ce test:
Je sélectionne le menu "doubles exacts".

Rien ne s'affiche, je n'ai aucun doublon.
Je crée un doublon avec le menu "Créer une version AIFF".

Je sélectionne le menu "doubles exacts".
Les deux morceaux sont affichés.


Pour être vraiment sûr, essaie le même test avec un morceau qui n'a pas de doublon, pour voir si les deux morceaux s'afficheront.