IPB

Bienvenue invité ( Connexion | Inscription )

> Bureau qui se désorganise, toutes les icones se groupent à droite de l'écran
Options
jacbuz
posté 27 Feb 2010, 08:52
Message #1


Adepte de Macbidouille
*

Groupe : Membres
Messages : 46
Inscrit : 23 Feb 2005
Lieu : Larra
Membre no 33 696



Bonjour à tous... J'ai un problème, et je ne suis pas le seul à l'avoir.
Le matin, à l'ouverture de mon iMac (27"), toutes les icones présentes sur le bureau, ne gardent plus la place initiale donnée la veille, mais se regroupent dans n'importe quel ordre, sur le côté droit de l'écran.
C'est fastidieux, désagréable, voire énervant.
Quelqu'un connaît-il : la raison ? et surtout la solution ?
Merci de votre aide.

JB OS 10.6.2
Go to the top of the page
 
+Quote Post
 
Start new topic
Réponse(s)
anael
posté 8 Mar 2010, 14:41
Message #2


Macbidouilleur de vermeil !
****

Groupe : Membres
Messages : 1 277
Inscrit : 6 Jul 2007
Lieu : Belgeek
Membre no 90 074



sucellus à mis à jour son code AppleScript (qui est même commenté)

Je l'ai testé sous Snow Leopard 10.6.2, il fonctionne sans problème ! Le voici ci-dessous.

C'est maintenant une solution relativement pratique à la désorganisation inopinée des icônes de bureau.

Un grand merci !

Citation
J'ai écrit un nouveau code, qui fait la même chose mais utilisable en application à placer au démarrage.

Code
-- Rangement des icônes sur le bureau
-- Légal Jean Louis (créé le 6 Novembre 2009 modifié 24 Février 2010)
-- Version 0.1.1 ß Testé avec Leopard 10.5.8

-- ATENTION le déplacement des icônes sur le bureau n'est accepté que suivant le réglage de la grille

-- \\\ VARIABLES IMPORTANTES POUR CE CODE /// --

property theList : missing value -- Mémoire
property listCtrl : missing value -- Mémoire de contrôle
property mem : false -- Pour affichage des fenêtres d'alertes (True OUI, False NON)

-- \\\ PREMIÈRE UTILISATION /// --

if theList is missing value then -- La mémoire est vide
    display dialog "Voulez-vous sauvegarder vos icônes à leur emplacement actuel ?" buttons {"Annuler", "Sauvegarder"} default button 2 with title "Sauvegarde des positions d'icônes"
    if (button returned of result) is "Annuler" then return -- Bouton Annuler, alors on quitte
    -- Lecture et écriture des noms et positions des icônes sur le bureau dans la variable de mémoire
    tell application "Finder" to set theList to {name, desktop position} of items of desktop
    -- On quitte le code
    
else
    
    -- \\\ UTILISATIONS SUIVANTES /// --
    
    tell application "Finder"
        -- Lecture des noms et positions des icônes sur le bureau pour faire des contrôles
        set listCtrl to {name, desktop position} of items of desktop
        -- Contrôle si le contenue la liste en mémoire est plus petite que celui de la liste de contrôle
        if ((count (first item of theList)) as integer) < ((count (first item of listCtrl)) as integer) then set mem to true
        -- Contrôle que les 2 listes sont identiques (mêmes noms aux icônes)
        if (first item of theList) does not contain (first item of listCtrl) then set mem to true
        -- Range seulement les icônes mémorisées
        repeat with i from 1 to (count (first item of theList))
            try -- Pour éviter les erreurs si un nom n'existe pas lors du rangement
                set desktop position of item (item i of first item of theList) of desktop to (item i of second item of theList)
            end try
        end repeat
        -- Si on supprime des icônes sans ajouts d'autres sur le bureau, les suppriment de la mémoire
        if ((count (first item of theList)) as integer) > ((count (first item of listCtrl)) as integer) then
            -- Mémorisation de la nouvelle liste des icônes sur le bureau
            tell application "Finder" to set theList to {name, desktop position} of items of desktop
            set mem to false -- Suppression d'icônes sans ajouts, donc pas de fenêtre d'alerte
        end if
    end tell
end if

-- \\\ DES MODIFICATIONS DONC DES NOUVELLES ICÔNES /// --

-- Si l'on ajoute où remplace des icônes par d'autres (donc changement de noms)
if mem is true then
    tell me to activate -- Etre sur que cette fenêtre seras en premier plan sur le bureau
    display dialog "Différence avec les icônes en mémoire et les icônes trouvées sur le bureau." buttons {"Annuler", "Sauvegarder"} default button 2 with title "Sauvegarder les positions des icônes"
    if (button returned of result) is "Annuler" then return -- Bouton Annuler, alors on quitte
    -- Mémorisation des noms et positions des icônes sur le bureau
    tell application "Finder" to set theList to {name, desktop position} of items of desktop
    set {listCtrl, mem} to {theList, false} -- Initialisation des variables
end if


Citation
Comment créer une application avec ce code ?

Léopard = Copier-Coller ce code dans Applications/AppleScript/Éditeur de scripts
Snow Léopard = Copier-Coller ce code dans Applications/Utilitaires/AppleScript Editor
Bouton Compiler (si le texte prend des couleurs, c'est bon).

Bouton Exécuter [ou Compiler, et le code se colore]

Barre des menus Fichier/Enregistrer sous…
Donner un nom.
Choisir où enregistrer l'application.
Léopard = Format de fichier : Progiciel (pour être compatible PPC et intel).
Snow Léopard = Format de fichier : Application.
Si écran de démarrage coché alors le décocher.
Enregistrer

Ensuite, placer l'application dans les préférences de votre compte utilisateur, onglet "Ouverture" (bouton "+")


--------------------

- iMac14,2 (27") Core i5 3,2 GHz - 24 Go RAM - Fusion Drive 1,12 To - macOS Catalina 10.15.7
- iPhone SE 2e - 128 Go - iOS 15.6
- iPad Pro M1 - 128 Go - iPadOS 15.6
- MacBook3,1 (blanc) Core 2 Duo 2,2 GHz - 4 Go RAM - HD 500 Go (7.200 tr/min) - Snow Leopard 10.6.8 & XP Pro SP3 (dual boot)


Bilan sécurité OS X

On ne voit bien qu'avec le coeur. L'essentiel est invisible pour les yeux.
Go to the top of the page
 
+Quote Post

Les messages de ce sujet
- jacbuz   Bureau qui se désorganise   27 Feb 2010, 08:52
- - SylvainBAIL   Cela m'arrive aussi de temps en temps, comme l...   27 Feb 2010, 09:00
- - jacbuz   Merci à Sylvain d'avoir répondu... Si quelqu...   28 Feb 2010, 07:32
|- - sucellus   Citation (jacbuz @ 28 Feb 2010, 07:32) Me...   28 Feb 2010, 09:57
- - anael   Je continue le recensement de ce bug... Donc, plus...   1 Mar 2010, 09:58
- - jacbuz   Bien reçu, merci.... Me reste plus qu'à. Je ...   1 Mar 2010, 10:03
- - anael   sucellus à mis à jour son code AppleScript (qui ...   8 Mar 2010, 14:41
|- - sucellus   Citation (anael @ 8 Mar 2010, 14:41) Bon...   8 Mar 2010, 15:56
|- - robertito   Citation (sucellus @ 8 Mar 2010, 10:56) C...   14 Aug 2010, 00:00
- - pampelune   Toujours pas de solution à ce problème ? C'e...   12 Aug 2010, 12:40
- - wotanbaby   Moi je suis architecte software, je travaille sur ...   12 Aug 2010, 13:55
- - wotanbaby   Bon d'accord, mon gros coup de gueule n'ar...   12 Aug 2010, 15:12
- - anael   Juste une question la langue de ton Snow Leopard, ...   12 Aug 2010, 20:11
- - wotanbaby   J'ai deux sessions qui sont pratiquement des c...   12 Aug 2010, 22:50
|- - anael   Citation (wotanbaby @ 12 Aug 2010, 23:50)...   13 Aug 2010, 14:12
- - wotanbaby   Bon c'est vrai que je suis plus trop souvent a...   13 Aug 2010, 19:35
- - david353   J'ai régulièrement le même problème depuis...   29 Oct 2010, 10:44
|- - sucellus   Citation (david353 @ 29 Oct 2010, 11:44) ...   31 Aug 2012, 11:34
- - anonym_d019ede3   Citation (david353 @ 29 Oct 2010, 11:44) ...   29 Oct 2010, 10:51
- - david353   J'ai regardé mais je n'ai pas vraiment be...   29 Oct 2010, 11:10
|- - sucellus   Citation (david353 @ 29 Oct 2010, 12:10) ...   29 Oct 2010, 11:38
|- - anael   Citation (sucellus @ 29 Oct 2010, 12:38) ...   29 Oct 2010, 22:06
- - maxjean2   Je reviens sur un article vieux de quelques mois, ...   20 Nov 2011, 10:01
|- - sucellus   Citation (maxjean2 @ 20 Nov 2011, 10:01) ...   20 Nov 2011, 10:56
- - maxjean2   Salut Sucellus A la mise en route, je n'ai qu...   21 Nov 2011, 15:24
|- - sucellus   Citation (maxjean2 @ 21 Nov 2011, 15:24) ...   21 Nov 2011, 19:00
- - alias44   Pour tous ceux qui ont des problèmes d'icône...   30 Dec 2011, 09:52
- - tataule   Je viens de passer à Snow Leopard (portable et Im...   31 Aug 2012, 10:09
|- - amaleyran   Citation (tataule @ 31 Aug 2012, 11:09) J...   31 Aug 2012, 10:49
- - tataule   Merci. J'ai trouvé un petit logiciel "DI...   31 Aug 2012, 14:14
|- - sucellus   Citation (tataule @ 31 Aug 2012, 15:14) M...   31 Aug 2012, 18:35
- - sitino   Merci sucellus. Semble fonctionnel sous SL 10.6.8....   28 Dec 2012, 09:59


Reply to this topicStart new topic
1 utilisateur(s) sur ce sujet (1 invité(s) et 0 utilisateur(s) anonyme(s))
0 membre(s) :

 



Nous sommes le : 28th March 2024 - 23:47